blob: 90c83aa38d45244eef37e843eb957e6cf1ee6b5a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
|
# Contributor: T.J. Townsend <blakkheim@archlinux.org>
# Contributor: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Bartłomiej Piotrowski <nospam@bpiotrowski.pl>
# Maintainer: tee < teeaur at duck dot com >
pkgbase=vbam
pkgname=(
vbam-sdl
vbam-wx
)
pkgver=2.2.3
pkgrel=1
pkgdesc='Nintendo GameBoy Advance emulator'
arch=(x86_64)
url='https://visualboyadvance-m.org'
license=('GPL-2.0-only')
depends=(
glu
libgl
libpng
sdl2
zlib
openal
)
makedepends=(
cmake
ffmpeg
git
libglvnd
ninja
wxwidgets-gtk3
zip
)
_pkgname=visualboyadvance-m
source=("git+https://github.com/${_pkgname}/${_pkgname}.git?signed#tag=v${pkgver}")
#source=("https://github.com/${_pkgname}/${_pkgname}/archive/v$pkgver.tar.gz")
b2sums=('0a9ad88c99d08845fd7bb1769a589ad5e7153cadbb2df389d1389e43b7b7bb2bd4cfbcd8038c3767133b61d0d798507b153eb3c1b9d3c1f3db7a167045dbccf7')
validpgpkeys=('A0C0E526E36FD2138C149D4D08AB596679D86240' # Rafael Kitover <rkitover@gmail.com>
'A4E3697D524B238DECCF3A17EB0E0FF1C62782D8' # Zach Bacon <zachbacon@vba-m.com>
)
prepare() {
cd ${_pkgname}
#cp cmake/FindAppleFFMPEG.cmake cmake/FindFFMPEG.cmake
}
build() {
cmake -S ${_pkgname} -B build-sdl -G Ninja \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_INSTALL_SYSCONFDIR=/etc \
-DCMAKE_SKIP_RPATH=TRUE \
-DENABLE_SDL=TRUE \
-DENABLE_WX=FALSE \
-DENABLE_LINK=FALSE \
-DBUILD_TESTING=OFF \
-Wno-dev
cmake --build build-sdl
cmake -S ${_pkgname} -B build-wx -G Ninja \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_INSTALL_SYSCONFDIR=/etc \
-DCMAKE_SKIP_RPATH=TRUE \
-DENABLE_SDL=FALSE \
-DENABLE_WX=TRUE \
-DENABLE_FFMPEG=TRUE \
-DENABLE_LINK=FALSE \
-DBUILD_TESTING=OFF \
-Wno-dev
cmake --build build-wx
}
package_vbam-sdl() {
backup=(etc/vbam.cfg)
conflicts=(vbam-wx)
DESTDIR="${pkgdir}" cmake --install build-sdl
}
package_vbam-wx() {
depends+=(
glib2
gtk3
libavcodec.so
libavformat.so
libavutil.so
libswscale.so
openal
wxwidgets-gtk3
zip
libxss
)
conflicts=(vbam-sdl)
DESTDIR="${pkgdir}" cmake --install build-wx
}
# vim: ts=2 sw=2 et:
|