blob: c7e1d9e2b81708711c0d32c1d7680439cdb54c00 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Maintainer: Caleb Maclennan <caleb@alerque.com>
# Contributor: Evan Pitstick <nerdx00 at gmail dot com>
# Contributor: Chet Gray <chetgray@gmail.com>
# Contributor: joni <kljohann@gmail.com>
# Contributor: Dieter Plaetinck <dieter@plaetinck.be>
pkgname=vcsh
pkgver=1.20190619
pkgrel=3
pkgdesc='Version Control System for $HOME that manages multiple Git repositories'
arch=('any')
url="https://github.com/RichiH/$pkgname"
license=('GPL')
depends=('git')
makedepends=('ruby-ronn')
checkdepends=('perl' 'perl-shell-command' 'perl-test-most')
optdepends=('myrepos: helps manage a large number of repositories')
source=("$pkgname-$pkgver.tar.gz::https://github.com/RichiH/$pkgname/archive/v$pkgver.tar.gz")
sha256sums=('9f9373bd96dfa1317ff119b2a3feaffc0e5331816e940267daf088637f995f5f')
prepare() {
cd "$pkgname-$pkgver"
sed -i 's#^\(install:\) all#\1 manpages#' Makefile
}
build() {
cd "$pkgname-$pkgver"
make manpages
}
check() {
cd "$pkgname-$pkgver"
make test
}
package() {
cd "$pkgname-$pkgver"
make DESTDIR="$pkgdir/" ZSHDIR='$(PREFIX)/share/zsh/site-functions' all='' install
}
|