blob: 1f42bca0e5298aa60b2236552c164c2e9456ae6f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: Caleb Maclennan <caleb@alerque.com>
# Contributor: Evan Pitstick <nerdx00 at gmail dot com>
# Contributor: Chet Gray <chetgray@gmail.com>
# Contributor: joni <kljohann@gmail.com>
# Contributor: Dieter Plaetinck <dieter@plaetinck.be>
pkgname=vcsh-git
pkgver=2.0.8.r1.g86b95ed
pkgrel=1
epoch=1
pkgdesc='Version Control System for $HOME that manages multiple Git repositories'
arch=(any)
url="https://github.com/RichiH/${pkgname%-git}"
license=(GPL-2.0-only)
depends=(git)
makedepends=(ruby-ronn)
checkdepends=(perl
perl-shell-command
perl-test-most)
optdepends=('myrepos: manage multiple vcsh repos through mr')
provides=("${pkgname%-git}=$pkgver")
conflicts=("${pkgname%-git}")
source=("$pkgname::git+$url.git")
sha256sums=('SKIP')
prepare() {
cd "$pkgname"
./bootstrap.sh
}
pkgver() {
cd "$pkgname"
git describe --long --tags --abbrev=7 HEAD |
sed 's/^v//;s/-\(alpha\|beta\|rc\)\./\1/;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "$pkgname"
./configure --prefix /usr
make
}
check() {
cd "$pkgname"
make test
}
package() {
cd "$pkgname"
make DESTDIR="$pkgdir" install
}
|