blob: 78b0251405cdbef5307cad4f31661c731b0a7e7a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer: OSAMC <https://github.com/osam-cologne/archlinux-proaudio>
# Contributor: Florian Hülsmann
_slug=voxglitch
_name=voxglitch
pkgname=vcvrack-voxglitch
pkgver=2.40.0
pkgrel=1
pkgdesc='Voxglitch VCV Rack modules'
arch=(aarch64 x86_64)
url='https://github.com/clone45/voxglitch'
license=(GPL-3.0-or-later)
groups=(pro-audio vcvrack-plugins)
depends=(gcc-libs vcvrack)
makedepends=(git jq simde zstd)
# get release commit from https://github.com/VCVRack/library/issues/626
_commit=c1efdd2d6d54964090745fbeb8c0140f1cdcb0c8
source=("git+https://github.com/clone45/$_name#commit=$_commit")
sha256sums=('be1f024a750d37d26156c9e30f1213e79a3690b06cb7e42b2f799ca19377075c')
prepare() {
cd $_name
if [ $(jq -r .version plugin.json) != $pkgver ]; then
echo "Make sure to update _commit"
false
fi
# common license
rm LICENSE
# https://github.com/clone45/voxglitch/issues/217#issuecomment-2690344027
sed -i -e 's/reserve/resize/g' src/vgLib-2.0/widgets/WaveformWidget.hpp
}
build() {
cd $_name
make SLUG=$_slug VERSION=$pkgver STRIP=: RACK_DIR=/usr/share/vcvrack dist
}
package() {
cd $_name
install -d "$pkgdir"/usr/lib/vcvrack/plugins
cp -va dist/$_slug -t "$pkgdir"/usr/lib/vcvrack/plugins
}
|