blob: 5eda7c6bae76ae9563a0ec8305073e35a4de9999 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# This PKGBUILD is part of the VDR4Arch project [https://github.com/vdr4arch]
# Maintainer: Alexander Grothe <seahawk1986[at]hotmail[dot]com>
pkgname=vdr-markad
pkgver=0.1.4_45_gea2e182
epoch=1
_gitver=ea2e182ec798375f3830f8b794e7408576f139ad
_vdrapi=2.4.0
pkgrel=2
pkgdesc="automatic advertisement detection"
url="http://projects.vdr-developer.org/projects/plg-markad"
arch=('x86_64' 'i686' 'arm' 'armv6h' 'armv7h')
license=('GPL2')
depends=('ffmpeg' "vdr-api=${_vdrapi}")
makedepends=('git')
_plugname=${pkgname//vdr-/}
source=("git+https://projects.vdr-developer.org/git/vdr-plugin-markad.git#commit=$_gitver"
"vdr-markad-ffmpeg4-fix.patch"
"vdr-markad-newmakefile.diff"
"50-$_plugname.conf")
backup=("etc/vdr/conf.avail/50-$_plugname.conf")
md5sums=('SKIP'
'118d57db2dd99bf5fbb829e2e55887ed'
'77001bbf5f138d1d1cd7a6f334fa8202'
'c0d6383c9c9b8ee6c34af19179676bf3')
pkgver() {
cd "${srcdir}/vdr-plugin-${_plugname}"
git describe --tags | sed 's/-/_/g;s/v//'
}
prepare() {
cd "${srcdir}/vdr-plugin-${_plugname}"
patch -p1 -i "$srcdir/vdr-markad-newmakefile.diff"
patch -p1 -i "$srcdir/vdr-markad-ffmpeg4-fix.patch"
}
build() {
cd "${srcdir}/vdr-plugin-${_plugname}"
make
}
package() {
cd "${srcdir}/vdr-plugin-${_plugname}"
make DESTDIR="$pkgdir" install
#Move the logofiles to the right place and add a symlink to workaround patching.
mkdir -p "$pkgdir/usr/share"
mv "$pkgdir/var/lib/markad" "$pkgdir/usr/share/markad"
ln -s /usr/share/markad "$pkgdir/var/lib/markad"
install -Dm644 "$srcdir/50-$_plugname.conf" "$pkgdir/etc/vdr/conf.avail/50-$_plugname.conf"
}
|