blob: a57c2f43e62fe916207f967e93cdc34ce2b1fd5f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# This PKGBUILD is part of the VDR4Arch project [https://github.com/vdr4arch]
# Maintainer: Christopher Reimer <mail+vdr4arch[at]c-reimer[dot]de>
pkgname=vdr-softhddevice
pkgver=0.7.0_100_ga40bb7f
epoch=1
_gitver=a40bb7f2d41ad7c5380f980d64842aa79cd05d2c
_vdrapi=2.4.1
pkgrel=1
pkgdesc="software and GPU emulated HD output device plugin for VDR"
url="https://github.com/ua0lnj/vdr-plugin-softhddevice"
arch=('x86_64' 'i686')
license=('AGPL3')
depends=('ffmpeg' 'freeglut' 'glew' 'mesa' "vdr-api=${_vdrapi}" 'xcb-util-wm' 'xorg-server')
optdepends=('nvidia: Required for VDPAU decoding',
'vdr-xorg: Recommended way to start X.org server together with VDR')
makedepends=('git' 'glm' 'glu' 'ffnvcodec-headers')
_plugname=${pkgname//vdr-/}
source=("git+https://github.com/ua0lnj/vdr-plugin-softhddevice.git#commit=$_gitver"
"50-$_plugname.conf")
backup=("etc/vdr/conf.avail/50-$_plugname.conf")
sha256sums=('SKIP'
'67bb0c168042b27ead3f62a98f9b434d0164da5fe334a76ccc5dd061932d1952')
pkgver() {
cd "${srcdir}/vdr-plugin-${_plugname}"
git tag -f 0.7.0 282c346a74b3c9e4ad73843f0759b4701a6d030e
git describe --tags | sed 's/-/_/g;s/v//'
}
prepare() {
cd "${srcdir}/vdr-plugin-${_plugname}"
# Disable OSS. Arch Linux doesn't ship OSS
sed -i '/OSS /d' Makefile
# Enable this to increase AV_INFO logging
#sed -i 's/3000/500/g' Makefile
# Enable this to compile with debug logging
#sed -i 's/# -DDEBUG/-DDEBUG/g' Makefile
}
build() {
cd "${srcdir}/vdr-plugin-${_plugname}"
make
}
package() {
cd "${srcdir}/vdr-plugin-${_plugname}"
make DESTDIR="${pkgdir}" install
install -Dm644 "$srcdir/50-$_plugname.conf" "$pkgdir/etc/vdr/conf.avail/50-$_plugname.conf"
}
|