PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35

# Maintainer: David Runge <dave@sleepmap.de>
pkgname=veejay-server-git
_name=veejay-server
_pkgroot=veejay
pkgver=1.5.57.r984.g560172d7
pkgrel=1
pkgdesc="Veejay is a visual instrument and realtime video sampler for GNU/Linux"
arch=('i686' 'x86_64')
url="https://github.com/c0ntrol/${_pkgroot}"
groups=('veejay')
conflicts=('veejay-server')
replaces=('veejay-server')
provides=('veejay-server')
license=('LGPL')
depends=('libxml2' 'libx11' 'jack' 'ffmpeg' 'sdl' 'gtk2' 'libjpeg-turbo')
makedepends=('git')
source=("${_name}::git+https://github.com/c0ntrol/${_pkgroot}")
sha512sums=('SKIP')

pkgver() {
  cd "$srcdir/${_name}/${_pkgroot}-current"
  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^v//g'
}

build() {
  cd "$srcdir/${_name}/${_pkgroot}-current/${_name}"
  ./autogen.sh
  ./configure --prefix=/usr
  make 2>&1 | tee build.log
}

package() {
  cd "$srcdir/${_name}/${_pkgroot}-current/${_name}"
  make DESTDIR="$pkgdir" install
}