summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 1139d4fa4667ed14713190d5b20661d8e186d0dd (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
# Maintainer: Brian Bidulock <bidulock@openss7.org>
# Contributor: Trizen <trizenx at gmail dot com>
# Contributor: Federico Cinelli <cinelli.federico@gmail.com>

pkgname=velox-git
pkgver=0.0.2.r255.gbde08e0
pkgrel=1
pkgdesc="A simple xcb window manager inspired by awesome, xmonad, and dwm."
arch=('i686' 'x86_64')
url="http://www.ohloh.net/p/velox-wm"
license=('MIT')
depends=('swc-git')
conflicts=('velox')
provides=('velox')
source=("$pkgname::git+https://github.com/michaelforney/velox.git")
md5sums=('SKIP')

pkgver() {
  cd $pkgname
  git describe --tags --long | sed -r 's/([^-]*-g)/r\1/;s/-/./g'
}

build() {
  cd $pkgname
  tee config.mk <<EOF
PREFIX = /usr
LIBEXECDIR = /usr/lib
V = 1
EOF

  make
}

package() {
  cd $pkgname
  make DESTDIR="$pkgdir" install
}

# vim: ft=sh syn=sh et