PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86

# Maintainer: justbispo <aur.fyxy0@slmail.me>
pkgname=(
    vencord
    chromium-vencord
    firefox-vencord
    firefox-developer-edition-vencord
    librewolf-vencord
)
pkgbase=vencord
_pkgname=Vencord
pkgver=1.14.2
pkgrel=1
pkgdesc="The cutest Discord client mod"
arch=(any)
url=https://vencord.dev
_ghurl="https://github.com/Vendicated/Vencord"
license=(GPL3)
makedepends=(
    git
    pnpm
)
source=("git+$_ghurl.git#tag=v$pkgver")
sha256sums=('88c36a762639d1a0696bb724c803eefa6917131a9c84976ec2f0b50fa477e9da')

prepare() {
    cd "$srcdir"/$_pkgname
    pnpm install --frozen-lockfile
}

build() {
    cd "$srcdir"/$_pkgname
    pnpm buildStandalone && pnpm buildWeb
}

check() {
    cd "$srcdir"/$_pkgname
    pnpm test && pnpm testWeb
}

package_vencord() {
    pkgdesc+=" (replaces Vesktop's built-in Vencord)"
    depends=(vesktop)
    install=vencord.install

    cd "$srcdir"/$_pkgname
    install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgbase/LICENSE
    install -Dm644 README.md "$pkgdir"/usr/share/doc/$pkgbase/README.md
    cd dist/
    install -d "$pkgdir"/usr/lib/$pkgbase
    cp -r -- vencord* preload* patcher* renderer* "$pkgdir"/usr/lib/$pkgbase
    echo '{}' >>"$pkgdir"/usr/lib/$pkgbase/package.json
}

package_chromium-vencord() {
    pkgdesc+=' (unpacked webextension)'
    optdepends=(chromium vivaldi google-chrome opera brave ungoogled-chromium)
    install=vencord.install

    cd "$srcdir"/$_pkgname/dist/chromium-unpacked
    install -dm755 "$pkgdir"/usr/lib/"$pkgbase"-chromium
    cp -r -- * "$pkgdir"/usr/lib/"$pkgbase"-chromium
}

package_firefox-vencord() {
    depends=(firefox)
    install=vencord.install

    cd "$srcdir"/$_pkgname/dist
    install -Dm644 extension-firefox.zip "$pkgdir"/usr/lib/firefox/browser/extensions/vencord-firefox@vendicated.dev.xpi
}

package_firefox-developer-edition-vencord() {
    depends=(firefox-developer-edition)
    install=vencord.install

    cd "$srcdir"/$_pkgname/dist
    install -Dm644 extension-firefox.zip "$pkgdir"/usr/lib/firefox-developer-edition/browser/extensions/vencord-firefox@vendicated.dev.xpi
}

package_librewolf-vencord() {
    depends=(librewolf)
    install=vencord.install

    cd "$srcdir"/$_pkgname/dist
    install -Dm644 extension-firefox.zip "$pkgdir"/usr/lib/librewolf/browser/extensions/vencord-firefox@vendicated.dev.xpi
}