blob: db6cf78d4d5184e35522e85acac8c5058827dad2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer: Jose Riha <jose1711 gmail com>
# Contributor: Dennis Hamester <dennis.hamester@startmail.com>
# Contributor: rafasc
_pkgname=vifm
pkgname=$_pkgname-git
pkgver=0.12.r216.g85a70df1b
pkgrel=1
pkgdesc="Ncurses based file manager with vi like keybindings"
arch=('i686' 'x86_64')
url="http://vifm.info/"
license=('GPL')
depends=('ncurses' 'desktop-file-utils' 'file')
optdepends=('perl: vifm-convert-dircolors')
makedepends=('git')
install=$pkgname.install
conflicts=('vifm')
provides=('vifm')
source=("git+https://github.com/vifm/vifm.git")
sha256sums=('SKIP')
pkgver() {
cd "${srcdir}"/$_pkgname
git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/v//g'
}
prepare() {
cd "${srcdir}/${_pkgname}"
autoreconf -fiv
}
build() {
cd "${srcdir}"/$_pkgname
./configure --prefix=/usr \
--sysconfdir=/etc
make
}
package() {
cd "${srcdir}"/$_pkgname
make DESTDIR="${pkgdir}" install
}
|