blob: e4146e0b17a3a94f0897071ab6c064720fa1002f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: Lukas Jirkovsky <l.jirkovsky@gmail.com>
pkgname=vigra-git
pkgver=3863.e360aa3
pkgrel=1
pkgdesc="Computer vision library"
arch=('i686' 'x86_64')
url="http://hci.iwr.uni-heidelberg.de/vigra/"
license=('custom:MIT')
depends=('libpng' 'libtiff' 'openexr' 'hdf5')
optdepends=('python2: vigra-config'
'boost-libs: python interface' 'python2: python interface' 'fftw: python interface')
# add doxygen to makedepends to build documentation
makedepends=('git' 'cmake' 'fftw' 'python2-numpy' 'boost')
checkdepends=('python2-nose')
provides=('vigra' 'vigra-hg')
conflicts=('vigra' 'vigra-hg')
replaces=('vigra-hg')
source=('git+git://github.com/ukoethe/vigra.git')
md5sums=('SKIP')
pkgver() {
cd "$srcdir/vigra"
echo $(git rev-list --count master).$(git rev-parse --short master)
}
build() {
cd "$srcdir/vigra"
cmake -DCMAKE_INSTALL_PREFIX=/usr \
-DPYTHON_EXECUTABLE=/usr/bin/python2 \
-DWITH_OPENEXR=true \
-DDOCINSTALL=share/doc \
-DCMAKE_SHARED_LINKER_FLAGS="-lpthread" \
.
make
}
check() {
cd "$srcdir/vigra"
make -k check
}
package() {
cd "$srcdir/vigra"
make DESTDIR="$pkgdir/" install
# fix for python2
sed -i 's|python$|python2|' "$pkgdir/usr/bin/vigra-config"
# license
install -D -m644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|