blob: a29bcc6e867000f2477b7cf5d8e842f14dd32cdf (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: Jeremy Audet <jerebear@protonmail.com>
pkgname=vim-dwm-git
_repository=dwm.vim
pkgver=6149e58 # see pkgver()
pkgrel=1
pkgdesc='Dynamic Window Manager behaviour for Vim'
arch=(any)
url='http://www.vim.org/scripts/script.php?script_id=4186'
license=(custom)
groups=(vim-plugins)
depends=(vim)
makedepends=(git)
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=("git+https://github.com/spolu/${_repository}.git")
sha256sums=(SKIP)
pkgver() {
cd "${_repository}"
git describe --always | sed 's/-/./g'
}
build() {
cd "${srcdir}/${_repository}"
sed -n '/Copyright:/,/Name Of File:/p' plugin/dwm.vim > LICENSE
}
package() {
cd "${srcdir}/${_repository}"
install -Dm 644 doc/dwm.txt \
"${pkgdir}/usr/share/vim/vimfiles/doc/dwm.txt"
install -Dm 644 plugin/dwm.vim \
"${pkgdir}/usr/share/vim/vimfiles/plugin/dwm.vim"
install -Dm 644 LICENSE \
"${pkgdir}/usr/share/licenses/$pkgname/LICENSE"
}
# vim:set ts=2 sw=2 et:
|