blob: d1edc1bdf7c2f8766a06ed5a80911de390c0f8d3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: Sainnhe Park <sainnhe@gmail.com>
_variant='vim'
_colorscheme='edge'
pkgbase="${_variant}-${_colorscheme}-git"
pkgname=("${_variant}-${_colorscheme}-git"
"${_variant}-airline-${_colorscheme}-git"
"${_variant}-lightline-${_colorscheme}-git")
pkgver=0.1.3.r4.g3231c16
pkgrel=1
arch=('any')
url="https://github.com/sainnhe/${_colorscheme}"
license=('MIT')
source=("${_colorscheme}::git+${url}.git")
sha256sums=('SKIP')
makedepends=('git')
pkgver() {
cd "${srcdir}/${_colorscheme}"
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
package_vim-edge-git() {
pkgdesc='Clean & Elegant Color Scheme inspired by Atom One and Material'
depends=("${_variant}")
provides=("${_variant}-${_colorscheme}")
conflicts=("${_variant}-${_colorscheme}")
cd "${srcdir}/${_colorscheme}"
find autoload/*.vim doc colors -type f -exec \
install -Dm 644 '{}' "${pkgdir}/usr/share/vim/vimfiles/{}" \;
install -Dm 644 "${srcdir}/${_colorscheme}/LICENSE" \
"${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
package_vim-airline-edge-git() {
pkgdesc="${_colorscheme} color scheme for airline"
depends=("${_variant}-${_colorscheme}"
'vim-airline')
provides=("${_variant}-airline-${_colorscheme}")
conflicts=("${_variant}-airline-${_colorscheme}")
cd "${srcdir}/${_colorscheme}"
find autoload/airline -type f -exec \
install -Dm 644 '{}' "${pkgdir}/usr/share/vim/vimfiles/{}" \;
}
package_vim-lightline-edge-git() {
pkgdesc="${_colorscheme} color scheme for lightline"
depends=("${_variant}-${_colorscheme}"
'vim-lightline-git')
provides=("${_variant}-lightline-${_colorscheme}")
conflicts=("${_variant}-lightline-${_colorscheme}")
cd "${srcdir}/${_colorscheme}"
find autoload/lightline -type f -exec \
install -Dm 644 '{}' "${pkgdir}/usr/share/vim/vimfiles/{}" \;
}
|