summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: a6d4a7f496ae5d5ea09da85aab9c2cd31a5204e3 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
# Maintainer: sekret, mail=$(echo c2VrcmV0QHBvc3Rlby5zZQo= | base64 -d)
# Contributor: Army
_pkgname=vim-latexsuite
pkgname=$_pkgname-git
pkgver=0.r913.0e832ae
pkgrel=1
epoch=1
pkgdesc="Provides a comprehensive set of tools to view, edit, and compile LaTeX documents within Vim. Also provides macros to speed up the creation of LaTeX documents."
arch=('any')
url="http://vim-latex.sourceforge.net"
license=('custom:vim')
groups=('vim-plugins')
depends=('vim-runtime')
makedepends=('git')
optdepends=('python2' 'texlive-bin')
provides=("$_pkgname")
conflicts=("$_pkgname")
install=$pkgname.install
source=("$_pkgname::git+https://github.com/vim-latex/vim-latex.git")
md5sums=('SKIP')

pkgver() {
  cd "$srcdir/$_pkgname"
  printf "0.r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  cd "$srcdir/$_pkgname"
  find . -type f -name *.py | xargs sed -i 's/\/usr\/bin\/python/\/usr\/bin\/env python2/g'
}

package() {
  cd "$srcdir/$_pkgname"
  make PREFIX="$pkgdir/usr" VIMDIR="$pkgdir/usr/share/vim/vimfiles" install
}

# vim:set ts=2 sw=2 et: