PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35

# Maintainer: fordprefect <fordprefect@dukun.de>
pkgname=vim3d-git
pkgver=r31.08774f3
pkgrel=1
pkgdesc="vi-style interface to 3D modeling and simulation built in C++ and OpenGL"
url="http://www.vim3d.com/"
arch=('x86_64' 'i686')
license=('custom')
depends=('freeglut' 'glu' 'mesa')
makedepends=('git')
source=("vim3d::git+https://github.com/pyramation/vim3d")
md5sums=('SKIP')

pkgver() {
      cd "$srcdir/vim3d"
      printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
 
build() {
    cd "${srcdir}/vim3d/src"
    make
}
  
package() {
    # binary
    install -D "${srcdir}/vim3d/src/vim3d" "${pkgdir}/usr/bin/vim3d"

    # support files
    mkdir -p "${pkgdir}"/usr/share/{doc/vim3d,vim3d}
    cp -r "${srcdir}"/vim3d/docs/* "${pkgdir}/usr/share/doc/vim3d"
    cp -r "${srcdir}"/vim3d/{scenes,textures,objects,Channels} "${pkgdir}/usr/share/vim3d/"

    # license
    install -Dm444 "${srcdir}/vim3d/LICENSE.txt" "${pkgdir}/usr/share/licenses/vim3d-git/LICENSE"
}