blob: 011738a06f049030d278002471b37ea1dfc77af5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer: imskyyc <sky at imskyyc dot com>
# shellcheck shell=bash disable=SC2034
_pkgname=vinegar
pkgname=vinegar-git
pkgrel=2
pkgver=v1.7.4.r26.gf50bcf6
pkgdesc="Fast and robust bootstrapper for Roblox that has many ease-of-use features."
arch=("x86_64")
url="https://github.com/vinegarhq/vinegar"
license=("GPL-3.0-only")
depends=("glibc" "hicolor-icon-theme" "libgles" "libxcursor" "libxfixes"
"libxkbcommon" "libxkbcommon-x11" "libx11" "wayland")
makedepends=("git" "go" "vulkan-headers" "wayland-protocols")
optdepends=("gamemode: Gamemode integration"
"vulkan-driver: Vulkan support in GUI"
"wine: A required dependency (made optional for flexbility)")
conflicts=("vinegar")
source=("git+${url}")
sha256sums=("SKIP")
provides=("${pkgname}=${pkgver}");
pkgver() {
cd "$_pkgname"
# cutting off 'foo-' prefix that presents in the git tag
git describe --long --abbrev=7 | sed 's/^foo-//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "${srcdir}/${_pkgname}"
# HACK (FIXME): Don't rebuild the icons when installing them
# (upstream repo has them anyway and building them causes race conditions)
sed -i 's/install-icons: icons/install-icons:/' Makefile
make clean
}
build() {
cd "${srcdir}/${_pkgname}"
export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -modcacherw"
export CGO_LDFLAGS="${LDFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
make DESTDIR="${pkgdir}" PREFIX="/usr" all
}
package() {
cd "${srcdir}/${_pkgname}"
make DESTDIR="${pkgdir}" PREFIX="/usr" install
install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
}
|