PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31

# Maintainer: Ricardo (XenGi) Band <email@ricardo.band>
pkgbase=virtualfish
pkgname=('python-virtualfish' 'python2-virtualfish')
pkgver=1.0.6
pkgrel=6
pkgdesc="A virtualenv wrapper for the Fish shell"
arch=(any)
url="https://github.com/adambrenecki/virtualfish"
license=('MIT')
options=(!emptydirs)
install=virtualfish.install
_deps=('setuptools' 'setuptools-scm' 'virtualenv' 'pkgconfig' 'psutil' 'xdg')
makedepends=("${_deps[@]/#/python-}" "${_deps[@]/#/python2-}")
source=("${pkgbase}::git+https://github.com/adambrenecki/${pkgbase}.git#tag=${pkgver}")
sha256sums=('SKIP')

prepare() {
    cp -a "$srcdir/$pkgbase"{,-py2}
}

package_python-virtualfish() {
    depends=("${_deps[@]/#/python-}")
    cd "${srcdir}/${pkgbase}"
    python setup.py install --root="$pkgdir/" --optimize=1
}

package_python2-virtualfish() {
    depends=("${_deps[@]/#/python2-}")
    cd "${srcdir}/${pkgbase}-py2"
    python2 setup.py install --root="$pkgdir/" --optimize=1
}