blob: a863c0befa04f9806d03ce428e82f27f7e0ae4f9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Maintainer: Pig Monkey <pm@pig-monkey.com>
# Maintainer: Caltlgin Stsodaat <contact@fossdaily.xyz>
# Contributor: Javier Tiá <javier dot tia at gmail dot com>
pkgname='visidata'
pkgver=2.8
pkgrel=1
pkgdesc='Terminal spreadsheet multitool for discovering and arranging data'
arch=('any')
url='https://www.visidata.org'
_url_source='https://github.com/saulpw/visidata'
_url_pypi='https://pypi.org/project/visidata'
license=('GPL3')
depends=('python-dateutil')
makedepends=('python-setuptools')
optdepends=('python-dnslib: pcap support'
'python-dpkt: pcap support' # AUR
'python-fonttools: ttf/otf support'
'python-h5py: hdf5 support'
'python-lxml: html/xml support'
'python-mapbox-vector-tile: mbtiles support' # AUR
'python-namestand: graphviz support' # AUR
'python-openpyxl: xlsx support'
'python-pandas: dta (Stata) support'
'python-pdfminer: pdf support'
'python-psycopg2: postgres support'
'python-pypng: png support'
'python-pyshp: shapefiles support' # AUR
'python-requests: http support'
'python-tabulate: tabulate saver support'
'python-vobject: vcf support'
'python-wcwidth: tabulate saver with unicode support'
'python-xlrd: xls support'
'python-pyaml: yaml/yml support')
source=("https://files.pythonhosted.org/packages/source/${pkgname::1}/${pkgname}/${pkgname}-${pkgver}.tar.gz")
sha256sums=('26d6cdacdca394a4820bda7f142746e190c49a7871c109f477f8ffddc1ccd0c9')
prepare() {
# Set correct permissions
cd "${pkgname}-${pkgver}"
chmod -c 644 "${pkgname}/man/"*
chmod -c 644 "${pkgname}.egg-info/"*
chmod -c 644 "${pkgname}/ddw/"*
}
build() {
cd "${pkgname}-${pkgver}"
python setup.py build
}
package() {
cd "${pkgname}-${pkgver}"
python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
install -Dvm644 'README.md' -t "${pkgdir}/usr/share/doc/${pkgname}"
}
# vim: ts=2 sw=2 et:
|