blob: 17a69c122ef0bfa6b58de137066c82152df338eb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
|
# Maintainer: eolianoe <eolianoe [at] gmail [DoT] com>
# Contributor: Filippo Squillace <sqoox85@gmail.com>
pkgname=visit-build
_pkgname=visit
pkgver=2.9.2
_pkgver=2_9_2
pkgrel=1
pkgdesc="Interactive parallel visualization and graphical analysis tool (built with build_visit)."
arch=('i686' 'x86_64')
url="https://wci.llnl.gov/simulation/computer-codes/visit"
_url="http://portal.nersc.gov"
license=('BSD' 'custom')
makedepends=('qtchooser' 'cmake' 'svn' 'java-runtime' 'gcc-fortran')
depends=('qtwebkit' 'python2-numpy' 'openmpi' 'glu' 'java-environment')
conflicts=('visit' 'visit-bin')
provides=('visit')
source=("${_url}/svn/${_pkgname}/trunk/releases/${pkgver}/build_${_pkgname}${_pkgver}"
"visit.sh")
sha256sums=('4b1d396b41923b3b2c1b2da2524cb424f0166d9898d04f367f52a0426ae7a688'
'd07a11e67ad646579fbc341f30e1eb63ebd38a5fbdd4f3ea36e8f460419028da')
prepare(){
cd ${srcdir}
# Fix to use python2
sed -i 's/python-config/python2-config/g' build_${_pkgname}${_pkgver}
sed -i 's/PYTHON_COMMAND="python"/PYTHON_COMMAND="python2"/g' build_${_pkgname}${_pkgver}
}
build() {
cd "${srcdir}"
export PAR_COMPILER=/usr/bin/mpicxx
export PAR_INCLUDE=-I/usr/include
export SILO_EXTRA_OPTIONS="LIBS='-lstdc++'"
export FC_COMPILER=gfortran
# To avoid some incompatibilities with Qt5
export QT_SELECT=4
mkdir -p build-${pkgver}
mkdir -p thirdparty-${pkgver}
# Fix in case the ${MAKEFLAGS} variable is empty
if [ -z "${MAKEFLAGS}" ]; then
MAKEFLAGS="-j1"
fi
echo yes | bash build_${_pkgname}${_pkgver} --console \
--installation-build-dir "${srcdir}/build-${pkgver}" \
--thirdparty-path "${srcdir}/thirdparty-${pkgver}" \
--system-cmake --system-qt --system-python \
--parallel-build --parallel \
--makeflags ${MAKEFLAGS} \
--cc gcc --cxx g++ --fortran \
--build-mode Release \
--java \
--pyside \
--silo \
--xdmf \
--netcdf \
--szip --zlib \
--hdf4 --hdf5
# Fix to use python2 in every scripts
cd "${srcdir}/build-${pkgver}/${_pkgname}${pkgver}"
sed -i 's/exec\ python/exec\ python2/' \
src/bin/frontendlauncher
sed -e "s|#![ ]*/usr/bin/python$|#!/usr/bin/python2|" \
-e "s|#![ ]*/usr/bin/env python$|#!/usr/bin/env python2|" \
-e "s|#![ ]*/bin/env python$|#!/usr/bin/env python2|" \
-i $(find . -name '*.py')
}
package(){
cd "${srcdir}/build-${pkgver}/${_pkgname}${pkgver}/src"
# The prefix could not be set in the build_visit script,
# because it will install it in the build function of the PKGBUILD.
sed -i 's/\/usr\/local/\/opt\/visit/' cmake_install.cmake
make install DESTDIR="${pkgdir}"
# License
install -Dm644 "${srcdir}/build-${pkgver}/${_pkgname}${pkgver}/src/COPYRIGHT" \
"${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE"
# Install script to set path
install -Dm755 "${srcdir}/visit.sh" "${pkgdir}/etc/profile.d/visit.sh"
}
# vim:set ts=2 sw=2 et:
|