blob: 7e36bca636d2f9ec6a6c01db05cae629acd75332 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Maintainer: BlackIkeEagle <ike DOT devolder AT gmail DOT com>
# Contributor: TZ86
pkgname=vivaldi
pkgver=1.0.344.37
pkgrel=1
pkgdesc='An advanced browser made with the power user in mind.'
url="https://vivaldi.com"
install=${pkgname}.install
options=(!strip !zipman)
license=('custom')
arch=('i686' 'x86_64')
depends=('gtk2' 'nss' 'libxtst' 'gconf' 'libxss' 'freetype2' 'ttf-font' 'desktop-file-utils' 'shared-mime-info' 'alsa-lib')
optdepends=(
'vivaldi-ffmpeg-codecs: playback of proprietary video/audio'
'google-chrome: Widevine DRM Plugin'
)
source_i686=("https://vivaldi.com/download/stable/vivaldi-beta-${pkgver}-1.i386.rpm")
source_x86_64=("https://vivaldi.com/download/stable/vivaldi-beta-${pkgver}-1.x86_64.rpm")
sha256sums_i686=('2ff91e98ac023e1b30bc8fdf468eb034c3a09de342225a6fa202efb15ea3f027')
sha256sums_x86_64=('1a20a0b3a691586774ee787b111bc5b84008a625c6bc62c90c258945b1c98089')
package() {
cp -a opt "$pkgdir"
install -dm755 "$pkgdir/usr/bin/"
# cheat to have the vivaldi path
mv "$pkgdir/opt/vivaldi-beta" "$pkgdir/opt/vivaldi"
# suid sanbox
chmod 4755 "$pkgdir/opt/vivaldi/vivaldi-sandbox"
# link to vivaldi from /usr/bin
ln -sf "/opt/vivaldi/vivaldi" "$pkgdir/usr/bin/vivaldi"
# fix internal vivaldi link
(
cd "$pkgdir/opt/vivaldi"
rm vivaldi
ln -s vivaldi-beta vivaldi
)
# install icons
for res in 16 22 24 32 48 64 128 256; do
install -Dm644 "$pkgdir/opt/vivaldi/product_logo_${res}.png" \
"$pkgdir/usr/share/icons/hicolor/${res}x${res}/apps/vivaldi.png"
done
# install desktop file
install -Dm644 usr/share/applications/vivaldi-beta.desktop \
"$pkgdir/usr/share/applications/vivaldi.desktop"
sed -e "s/-beta//g" -i "$pkgdir/usr/share/applications/vivaldi.desktop"
}
|