blob: 5c5032b7290ff85ca73f5269853f126115563f55 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: BlackIkeEagle <ike DOT devolder AT gmail DOT com>
# Contributor: TZ86
pkgname=vivaldi
pkgver=1.1.453.52
pkgrel=1
pkgdesc='An advanced browser made with the power user in mind.'
url="https://vivaldi.com"
options=(!strip !zipman)
license=('custom')
arch=('i686' 'x86_64')
depends=('gtk2' 'nss' 'libxtst' 'gconf' 'libxss' 'freetype2' 'ttf-font' 'desktop-file-utils' 'shared-mime-info' 'alsa-lib' 'hicolor-icon-theme')
makedepends=('w3m')
optdepends=(
'vivaldi-ffmpeg-codecs: playback of proprietary video/audio'
'google-chrome: Widevine DRM Plugin'
)
source_i686=("https://downloads.vivaldi.com/stable/vivaldi-stable-${pkgver}-1.i386.rpm")
source_x86_64=("https://downloads.vivaldi.com/stable/vivaldi-stable-${pkgver}-1.x86_64.rpm")
sha256sums_i686=('90c2448065971deb74169113d8f9a7107d045dd8f3ed421fd6520c017661da7e')
sha256sums_x86_64=('20e0876bcf207d8f4c456dfe7e9f295fd71892a2068139e8c6477b64a33c5cce')
package() {
cp -a {opt,usr} "$pkgdir"
# suid sanbox
chmod 4755 "$pkgdir/opt/vivaldi/vivaldi-sandbox"
# install icons
for res in 16 22 24 32 48 64 128 256; do
install -Dm644 "$pkgdir/opt/vivaldi/product_logo_${res}.png" \
"$pkgdir/usr/share/icons/hicolor/${res}x${res}/apps/vivaldi.png"
done
# license
install -dm755 "$pkgdir/usr/share/licenses/$pkgname"
strings "$pkgdir/opt/vivaldi/locales/en-US.pak" \
| tr '\n' ' ' \
| sed -rne 's/.*(<html lang.*>.*html>).*/\1/p' \
| w3m -I 'utf-8' -T 'text/html' \
> "$pkgdir/usr/share/licenses/$pkgname/eula.txt"
}
|