blob: dda41e29cde01a1f11d6272974d8995e5a07667a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
# Maintainer: BlackIkeEagle <ike DOT devolder AT gmail DOT com>
# Contributor: TZ86
pkgname=vivaldi
pkgver=1.14.1077.60
pkgrel=1
pkgdesc='An advanced browser made with the power user in mind.'
url="https://vivaldi.com"
options=(!strip !zipman)
license=('custom')
arch=('x86_64')
depends=('gtk3' 'libcups' 'nss' 'gconf' 'alsa-lib' 'libxss' 'ttf-font' 'desktop-file-utils' 'shared-mime-info' 'hicolor-icon-theme')
makedepends=('w3m')
optdepends=(
'vivaldi-ffmpeg-codecs: playback of proprietary video/audio'
'pepper-flash: flash support'
'google-chrome: Widevine DRM Plugin'
'vivaldi-widevine: Widevine DRM Plugin'
'libnotify: native notifications'
)
source_x86_64=("https://downloads.vivaldi.com/stable/vivaldi-stable-${pkgver}-1.x86_64.rpm")
sha512sums_x86_64=('168d9eea8be22e2fff352ad8bf20e806d7adc3030b8f13c77be8b3e77196e737d7d3037ec27c5ac4a7a922357728cb9fed36a7c64b7d51d476833c268f7c951e')
package() {
cp -a {opt,usr} "$pkgdir"
# suid sandbox
chmod 4755 "$pkgdir/opt/vivaldi/vivaldi-sandbox"
# make /usr/bin/vivaldi-stable available
binf="$pkgdir/usr/bin/vivaldi-stable"
if [[ ! -e "$binf" ]] && [[ ! -f "$binf" ]] && [[ ! -L "$binf" ]]; then
install -dm755 "$pkgdir/usr/bin"
ln -s /opt/vivaldi/vivaldi "$binf"
fi
# install icons
for res in 16 22 24 32 48 64 128 256; do
install -Dm644 "$pkgdir/opt/vivaldi/product_logo_${res}.png" \
"$pkgdir/usr/share/icons/hicolor/${res}x${res}/apps/vivaldi.png"
done
# license
install -dm755 "$pkgdir/usr/share/licenses/$pkgname"
strings "$pkgdir/opt/vivaldi/locales/en-US.pak" \
| tr '\n' ' ' \
| sed -rne 's/.*(<html lang.*>.*html>).*/\1/p' \
| w3m -I 'utf-8' -T 'text/html' \
> "$pkgdir/usr/share/licenses/$pkgname/eula.txt"
# quick fix for the actions
if ! grep 'Desktop Action' "$pkgdir/usr/share/applications/vivaldi-stable.desktop" > /dev/null 2>&1; then
cat <<'EOF' >> "$pkgdir/usr/share/applications/vivaldi-stable.desktop"
[Desktop Action new-window]
Name=New Window
Exec=/usr/bin/vivaldi-stable --new-window
TargetEnvironment=Unity
[Desktop Action new-private-window]
Name=New Private Window
Exec=/usr/bin/vivaldi-stable --incognito
TargetEnvironment=Unity
EOF
fi
}
|