PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75

# Maintainer: Feakster <feakster at posteo dot eu>
# Contributor: Felix Golatofski <contact at xdfr dot de>
# Contributor: Matthew Zilvar <mattzilvar at gmail dot com>
# Contributor: Térence Clastres <t dot clastres at gmail dot com>
# Modified PKGBUILD from https://aur.archlinux.org/packages/vivaldi/

### Info ###
pkgname=vivaldi-arm-bin
_pkgname=${pkgname%-arm-bin}
pkgver=3.6.2165.36
pkgrel=4
_pkgrel=1
pkgdesc='An advanced browser made with the power user in mind'
arch=('armv6h' 'armv7h' 'aarch64')
url="https://vivaldi.com"
license=('custom:Vivaldi EULA')
provides=('vivaldi' 'www-browser')
depends=('alsa-lib' 'desktop-file-utils' 'gtk3' 'hicolor-icon-theme' 'libcups' 'libxss' 'mesa' 'nss' 'shared-mime-info' 'ttf-font')
optdepends=(
    'libnotify: native notifications'
)
options=('!emptydirs' '!strip')
install="$pkgname.install"
_source_armhf=("https://downloads.vivaldi.com/stable/vivaldi-stable_${pkgver}-${_pkgrel}_armhf.deb")
source_armv6h=("$_source_armhf")
source_armv7h=("$_source_armhf")
source_aarch64=("https://downloads.vivaldi.com/stable/vivaldi-stable_${pkgver}-${_pkgrel}_arm64.deb")
b2sums_armv6h=('e814f57cd530024a4a179764814c6bb73c6a876c5b98f9f117fa74d49f3157c95e980dd82529059c8e455cb47da3c56c8d311af820391b30891992807993a534')
b2sums_armv7h=('e814f57cd530024a4a179764814c6bb73c6a876c5b98f9f117fa74d49f3157c95e980dd82529059c8e455cb47da3c56c8d311af820391b30891992807993a534')
b2sums_aarch64=('b95b4bc62639c46add743a2f8d66edbd2e6981bff3de7d7f3828ea82efe3295350a3eabb96a4a2cf41b45156c9b64f64b067208f73ca30c70dd716f5aebce12c')

### Prepare ###
prepare() {
    ## Extract Internals ##
    tar -xf data.tar.xz
}

### Package ###
package() {
    ## Copy Directory Structure ##
    cp --parents -a {opt,usr/share} "$pkgdir"
    
    ## SUID Sandbox ##
    chmod 4755 "$pkgdir"/opt/$_pkgname/${_pkgname}-sandbox
    
    ## Place Binary on System PATH ##
    install -dm0755 "$pkgdir"/usr/bin
    ln -fs \
    /opt/vivaldi/vivaldi \
    "$pkgdir"/usr/bin/${_pkgname}-stable
    
    ## Replace Shared Objects with Symlinks ##
    for SO in EGL GLESv2; do
        ln -fs \
        /usr/lib/${SO}.so \
        "$pkgdir"/opt/$_pkgname/lib${SO}.so
    done
    
    ## Install Icons ##
    for res in 16 22 24 32 48 64 128 256; do
        install -dm0755 "$pkgdir"/usr/share/icons/hicolor/${res}x${res}/apps
        ln -fs \
        /opt/$_pkgname/product_logo_${res}.png \
        "$pkgdir"/usr/share/icons/hicolor/${res}x${res}/apps/$_pkgname.png
    done
    
    ## License ##
    install -dm0755 "$pkgdir"/usr/share/licenses/$_pkgname
    ln -fs \
    /opt/$_pkgname/LICENSE.html \
    "$pkgdir"/usr/share/licenses/$_pkgname/LICENSE.html
    
    ## Remove Unnecessary Directories/Files ##
    rm -rf "$pkgdir"/opt/vivaldi/{cron,update-widevine,WidevineCdm}
}