blob: 8f6031818b3a9692af1091cf1ecae85ab95fe08d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Maintainer: BlackIkeEagle <ike DOT devolder AT gmail DOT com>
# Contributor: TZ86
pkgname=vivaldi-snapshot
_rpmversion=2.1.1328.4-2
pkgver=2.1.1328.4
pkgrel=1
pkgdesc='An advanced browser made with the power user in mind. Snapshot'
url="https://vivaldi.com"
options=(!strip !zipman)
license=('custom')
arch=('x86_64')
depends=('gtk3' 'libcups' 'nss' 'alsa-lib' 'libxss' 'ttf-font' 'desktop-file-utils' 'shared-mime-info' 'hicolor-icon-theme')
makedepends=('w3m' 'imagemagick')
optdepends=(
'vivaldi-snapshot-ffmpeg-codecs: playback of proprietary video/audio'
'pepper-flash: flash support'
'google-chrome: Widevine DRM Plugin'
'vivaldi-widevine: Widevine DRM Plugin'
'libnotify: native notifications'
)
source=("https://downloads.vivaldi.com/snapshot/vivaldi-snapshot-${_rpmversion}.x86_64.rpm")
sha512sums=('7e86216f4fabdecae1dedf10356f07b2eaf27e7edb79fc1539a9948ab27f4238dc7acf20fba930d78f29142a5accdc7ffa04a38ddbd3c9eec95650eaaa96572e')
package() {
cp -a {opt,usr} "$pkgdir"
# suid sandbox
chmod 4755 "$pkgdir/opt/$pkgname/vivaldi-sandbox"
# make /usr/bin/vivaldi-snapshot available
binf="$pkgdir/usr/bin/$pkgname"
if [[ ! -e "$binf" ]] && [[ ! -f "$binf" ]] && [[ ! -L "$binf" ]]; then
install -dm755 "$pkgdir/usr/bin"
ln -s /opt/$pkgname/$pkgname "$binf"
fi
# 256 and 24 are proper colored icons
for res in 128 64 48 32; do
convert "$pkgdir/opt/$pkgname/product_logo_256.png" \
-resize ${res}x${res} \
"$pkgdir/opt/$pkgname/product_logo_$res.png"
done
for res in 22 16; do
convert "$pkgdir/opt/$pkgname/product_logo_24.png" \
-resize ${res}x${res} \
"$pkgdir/opt/$pkgname/product_logo_$res.png"
done
# install icons
for res in 16 22 24 32 48 64 128 256; do
install -Dm644 "$pkgdir/opt/$pkgname/product_logo_${res}.png" \
"$pkgdir/usr/share/icons/hicolor/${res}x${res}/apps/$pkgname.png"
done
# license
install -dm755 "$pkgdir/usr/share/licenses/$pkgname"
strings "$pkgdir/opt/$pkgname/locales/en-US.pak" \
| tr '\n' ' ' \
| sed -rne 's/.*(<html lang.*>.*html>).*/\1/p' \
| w3m -I 'utf-8' -T 'text/html' \
> "$pkgdir/usr/share/licenses/$pkgname/eula.txt"
}
|