blob: fc443cbe064943dd341c2cb2daa53e4c59c0f238 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer: BlackIkeEagle <ike DOT devolder AT gmail DOT com>
# Contributor: TZ86
pkgname=vivaldi-snapshot
pkgver=1.10.829.3
pkgrel=1
pkgdesc='An advanced browser made with the power user in mind. (weekly snapshot)'
url="https://vivaldi.com"
options=(!strip !zipman)
license=('custom')
arch=('i686' 'x86_64')
depends=('gtk2' 'nss' 'libxtst' 'gconf' 'libxss' 'freetype2' 'ttf-font' 'desktop-file-utils' 'shared-mime-info' 'alsa-lib' 'hicolor-icon-theme')
optdepends=(
'vivaldi-snapshot-ffmpeg-codecs: playback of proprietary video/audio'
'google-chrome: Widevine DRM Plugin'
'vivaldi-widevine: Widevine DRM Plugin'
)
source_i686=("https://downloads.vivaldi.com/snapshot/vivaldi-snapshot-${pkgver}-1.i386.rpm")
source_x86_64=("https://downloads.vivaldi.com/snapshot/vivaldi-snapshot-${pkgver}-1.x86_64.rpm")
sha512sums_i686=('49b687145796a8af4aa30a9c6cef573bcb8cfadb495f6310e3fd028cc520362e7bf98d8ea3918ad1ddb36f1b097cb4d52461283a7fe8cbf12664530aae69b3f3')
sha512sums_x86_64=('72045c365673a3b77bd19bda02fd43b5e34ab621f89926768b9a0bb7c57a40268e097c7091c09355d6a92b2bf1acdf013a8e97a9f9f31d51b8a2ddebb75cc8ce')
package() {
cp -a {opt,usr} "$pkgdir"
# suid sanbox
chmod 4755 "$pkgdir/opt/vivaldi-snapshot/vivaldi-sandbox"
# make /usr/bin/vivaldi-snapshot available
binf="$pkgdir/usr/bin/vivaldi-snapshot"
if [[ ! -e "$binf" ]] && [[ ! -f "$binf" ]] && [[ ! -L "$binf" ]]; then
install -dm755 "$pkgdir/usr/bin"
ln -s /opt/$pkgname/$pkgname "$binf"
fi
# install icons
for res in 16 22 24 32 48 64 128 256; do
install -Dm644 "$pkgdir/opt/vivaldi-snapshot/product_logo_${res}.png" \
"$pkgdir/usr/share/icons/hicolor/${res}x${res}/apps/vivaldi-snapshot.png"
done
}
|