blob: 44451e536297b399e0c2a9457a0228c1730344f6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer: BlackIkeEagle <ike DOT devolder AT gmail DOT com>
# Contributor: TZ86
pkgname=vivaldi-snapshot
pkgver=1.10.834.9
pkgrel=1
pkgdesc='An advanced browser made with the power user in mind. (weekly snapshot)'
url="https://vivaldi.com"
options=(!strip !zipman)
license=('custom')
arch=('i686' 'x86_64')
depends=('gtk2' 'nss' 'libxtst' 'gconf' 'libxss' 'freetype2' 'ttf-font' 'desktop-file-utils' 'shared-mime-info' 'alsa-lib' 'hicolor-icon-theme')
optdepends=(
'vivaldi-snapshot-ffmpeg-codecs: playback of proprietary video/audio'
'google-chrome: Widevine DRM Plugin'
'vivaldi-widevine: Widevine DRM Plugin'
)
source_i686=("https://downloads.vivaldi.com/snapshot/vivaldi-snapshot-${pkgver}-1.i386.rpm")
source_x86_64=("https://downloads.vivaldi.com/snapshot/vivaldi-snapshot-${pkgver}-1.x86_64.rpm")
sha512sums_i686=('05162accf9ef2f995d92aa8bb02701ad9ffd3a711a4c2a6ff06203911e3d55f5e9df45aeb9954f888bcf84ea122e8fd908b5d8b7430b45a0a3348ffc5120c618')
sha512sums_x86_64=('db3d7283d72290845cb4fa1be96104e2f82289c16bb5cf2f4c6caf48cb61fdc5ee11d58389e982e491847a4bb8cc4422ee4b925a13b341fbd026fbb09936bac2')
package() {
cp -a {opt,usr} "$pkgdir"
# suid sanbox
chmod 4755 "$pkgdir/opt/vivaldi-snapshot/vivaldi-sandbox"
# make /usr/bin/vivaldi-snapshot available
binf="$pkgdir/usr/bin/vivaldi-snapshot"
if [[ ! -e "$binf" ]] && [[ ! -f "$binf" ]] && [[ ! -L "$binf" ]]; then
install -dm755 "$pkgdir/usr/bin"
ln -s /opt/$pkgname/$pkgname "$binf"
fi
# install icons
for res in 16 22 24 32 48 64 128 256; do
install -Dm644 "$pkgdir/opt/vivaldi-snapshot/product_logo_${res}.png" \
"$pkgdir/usr/share/icons/hicolor/${res}x${res}/apps/vivaldi-snapshot.png"
done
}
|