PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112

# Maintainer: Gustavo Alvarez <sl1pkn07@gmail.com>

pkgbase=vkd3d-git
pkgname=(
  'vkd3d-git'
  'lib32-vkd3d-git'
)
pkgver=1.15.365.g379b297d
pkgrel=1
arch=('x86_64')
url='https://source.winehq.org/git/vkd3d.git'
license=('LGPL')
makedepends=(
  'spirv-headers'
  'vulkan-headers'
  'xcb-proto'
  'wine'
  'spirv-tools'
  'lib32-spirv-tools'
  'vulkan-icd-loader'
  'lib32-vulkan-icd-loader'
  'libxcb'
  'lib32-libxcb'
  'ncurses'
  'lib32-ncurses'
)
conflicts=('vkd3d')
provides=('vkd3d')
source=('git+https://source.winehq.org/git/vkd3d.git')
sha256sums=('SKIP')
options=('debug')

pkgver() {
  cd vkd3d
  echo "$(git describe --long --tags | tr - . | sed 's|vkd3d.||')"
}

prepare() {
  mkdir -p build{32,64}

  git clone "file://${srcdir}/vkd3d" vkd3d32
}

build() {
  CPPFLAGS+=' -DVKD3D_SHADER_UNSUPPORTED_GLSL'

  cd "${srcdir}/vkd3d"
  ./autogen.sh

  cd "${srcdir}/build64"
  ../vkd3d/configure \
    --prefix=/usr \
    --with-spirv-tools

  make

  export CC="gcc -m32"
  export CXX="g++ -m32"
  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"

  cd "${srcdir}/vkd3d32"
  ./autogen.sh

  cd "${srcdir}/build32"
  ../vkd3d32/configure \
    --prefix=/usr \
    --libdir=/usr/lib32 \
    --with-spirv-tools \
    --host=i686-linux-gnu

  make
}

#disable due SPIRV fails
_check() {
  make -C build64 check
  make -C build32 check
}

package_vkd3d-git() {
  pkgdesc='D3D12 to Vulkan translation library. (GIT version)'
  depends=(
    'spirv-tools'
    'libvulkan.so'
    'libxcb'
    'ncurses'
  )
  provides=(
    'vkd3d'
    "vkd3d=${pkgver}"
  )
  conflicts=('vkd3d')
  make -C build64 DESTDIR="${pkgdir}" install
}

package_lib32-vkd3d-git() {
  pkgdesc='D3D12 to Vulkan translation library. (GIT version) (32-bits)'
  depends=(
    "vkd3d=${pkgver}"
    'lib32-spirv-tools'
    'libvulkan.so'
    'lib32-libxcb'
    'lib32-ncurses'
  )
  provides=('lib32-vkd3d')
  conflicts=('lib32-vkd3d')
  make -C build32 DESTDIR="${pkgdir}" install

  rm -fr "${pkgdir}/usr/include"
  mv "${pkgdir}/usr/bin/vkd3d-compiler" "${pkgdir}/usr/bin/vkd3d-compiler-32"
  mv "${pkgdir}/usr/bin/vkd3d-dxbc" "${pkgdir}/usr/bin/vkd3d-dxbc-32"
}