blob: 60bfd87c961deea815029da14ee79d3606d8ac39 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
|
# $Id: PKGBUILD 191972 2013-08-02 09:52:35Z bpiotrowski $
# Maintainer: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: Sarah Hay <sarahhay@mb.sympatico.ca>
# Contributor: Martin Sandsmark <martin.sandsmark@kde.org>
_pkgname=vlc
pkgname=vlc-decklink
pkgver=2.0.8.a
pkgrel=1
pkgdesc="A multi-platform MPEG, VCD/DVD, and DivX player (with decklink module)"
arch=('i686' 'x86_64')
url="http://www.videolan.org/vlc/"
license=('LGPL2.1' 'GPL2')
depends=('a52dec' 'libdvbpsi' 'libxpm' 'libdca' 'qt4' 'libproxy'
'sdl_image' 'libdvdnav' 'libtiger' 'lua51' 'libmatroska'
'zvbi' 'taglib' 'libmpcdec' 'ffmpeg-compat' 'faad2' 'libupnp'
'libshout' 'libmad' 'libmpeg2' 'xcb-util-keysyms')
makedepends=('live-media' 'libnotify' 'libbluray' 'flac' 'kdelibs'
'libdc1394' 'libavc1394' 'lirc-utils' 'libcaca' 'oss'
'librsvg' 'portaudio' 'oss' 'libgme' 'xosd' 'projectm'
'twolame' 'aalib' 'libmtp' 'libdvdcss' 'gnome-vfs'
'libgoom2' 'libtar' 'vcdimager' 'opus' 'libssh2' 'mesa'
'decklink-sdk')
optdepends=('avahi: for service discovery using bonjour protocol'
'libnotify: for notification plugin'
'ncurses: for ncurses interface support'
'libdvdcss: for decoding encrypted DVDs'
'lirc-utils: for lirc plugin'
'libavc1394: for devices using the 1394ta AV/C'
'libdc1394: for IEEE 1394 plugin'
'kdelibs: KDE Solid hardware integration'
'libva-vdpau-driver: vdpau back-end for nvidia'
'libva-intel-driver: back-end for intel cards'
'libbluray: for Blu-Ray support'
'flac: for Free Lossless Audio Codec plugin'
'oss: for OSS audio support'
'portaudio: for portaudio support'
'twolame: for TwoLAME mpeg2 encoder plugin'
'projectm: for ProjectM visualisation plugin'
'libcaca: for colored ASCII art video output'
'libgme: for libgme plugin'
'librsvg: for SVG plugin'
'gnome-vfs: for GNOME Virtual File System support'
'libgoom2: for libgoom plugin'
'vcdimager: navigate VCD with libvcdinfo'
'xosd: for xosd support'
'aalib: for ASCII art plugin'
'libmtp: for MTP devices support'
'smbclient: for SMB access plugin'
'libcdio: for audio CD playback support'
'ttf-freefont: for subtitle font '
'ttf-dejavu: for subtitle font'
'opus: for opus support'
'libssh2: for sftp support'
'decklink: for decklink support')
conflicts=('vlc-plugin' 'vlc')
provides=('vlc')
replaces=('vlc-plugin')
backup=('usr/share/vlc/lua/http/.hosts'
'usr/share/vlc/lua/http/dialogs/.hosts')
options=('!libtool' '!emptydirs')
install=vlc.install
source=("http://download.videolan.org/pub/videolan/${_pkgname}/${pkgver/.a}/${_pkgname}-${pkgver/.a/a}.tar.xz"
vlc-2.0.7-vaapi-compat.patch
vlc-2.0.8-Fix-live555-breakage-in-last-update.patch)
md5sums=('e5000677181406d026ffe448633d1ca0'
'6df10774bb7acf20e09d6139e5c7839e'
'e592efe7bb65291a84f99cfaa3a9f8a2')
prepare() {
cd "${srcdir}/${_pkgname}-${pkgver/.a}"
patch -Np1 -i ../vlc-2.0.7-vaapi-compat.patch
patch -Np1 -i ../vlc-2.0.8-Fix-live555-breakage-in-last-update.patch
# dirty hack because of VLC's configure
[ -d decklink-sdk ] || mkdir decklink-sdk
ln -sf /usr/src/decklink-sdk decklink-sdk/include
sed -i -e 's:truetype/freefont:TTF:g' modules/text_renderer/freetype.c
sed -i -e 's:truetype/ttf-dejavu:TTF:g' modules/visualization/projectm.cpp
}
build() {
cd "${srcdir}/${_pkgname}-${pkgver/.a}"
CFLAGS+="-I/usr/include/samba-4.0" CPPFLAGS+="-I/usr/include/samba-4.0" \
PKG_CONFIG_PATH+="/usr/lib/ffmpeg-compat/pkgconfig" \
./configure --prefix=/usr \
--sysconfdir=/etc \
--disable-rpath \
--enable-oss \
--enable-faad \
--enable-nls \
--enable-lirc \
--enable-pvr \
--enable-ncurses \
--enable-realrtsp \
--enable-xosd \
--enable-aa \
--enable-vcdx \
--enable-upnp \
--enable-opus \
--enable-sftp \
--enable-decklink \
--with-decklink-sdk="${srcdir}/${_pkgname}-${pkgver}/decklink-sdk" \
LUAC=luac5.1 \
RCC=/usr/bin/rcc-qt4
make
}
package() {
cd "${srcdir}/${_pkgname}-${pkgver/.a}"
make DESTDIR="${pkgdir}" install
for res in 16 32 48 128; do
install -D -m644 "${srcdir}/vlc-${pkgver/.a}/share/icons/${res}x${res}/vlc.png" \
"${pkgdir}/usr/share/icons/hicolor/${res}x${res}/apps/vlc.png"
done
}
|