blob: 88cfe5b4e618fc1703ebd6b1007ac4111a8bb607 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Daniel Bermond <dbermond@archlinux.org>
pkgname=vmaf-git
pkgver=1.5.1.r0.g35c6044
pkgrel=1
pkgdesc='Perceptual video quality assessment algorithm based on multi-method fusion (git version)'
arch=('x86_64')
url='https://github.com/Netflix/vmaf/'
license=('BSD')
depends=('gcc-libs')
makedepends=('git' 'meson')
provides=('vmaf' 'libvmaf-git')
conflicts=('vmaf' 'libvmaf-git')
replaces=('libvmaf-git')
source=('git+https://github.com/Netflix/vmaf.git')
sha256sums=('SKIP')
prepare() {
mkdir -p vmaf/libvmaf/build
}
pkgver() {
cd vmaf
git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^v//'
}
build() {
arch-meson vmaf/libvmaf/build vmaf/libvmaf
ninja -v -C vmaf/libvmaf/build
}
check() {
ninja -v -C vmaf/libvmaf/build test
}
package() {
DESTDIR="$pkgdir" ninja -v -C vmaf/libvmaf/build install
local _bin
install -D -m755 vmaf/libvmaf/build/tools/vmaf -t "${pkgdir}/usr/bin"
for _bin in moment ms_ssim psnr ssim
do
install -D -m755 "vmaf/libvmaf/build/tools/${_bin}" "${pkgdir}/usr/bin/vmaf-${_bin}"
done
install -D -m644 vmaf/LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
}
|