summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: c2f2825c6754924d500b8d85c76b1cd8b9b31972 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
# Maintainer: Fabio 'Lolix' Loli <lolix@disroot.org>
# Contributor: erk <v at erk dot io>

pkgname=vnote
pkgver=2.8.1
pkgrel=1
pkgdesc="A Vim-inspired note-taking application, especially for Markdown."
arch=(x86_64 i686 arm armv6h armv7h aarch64)
url="https://tamlok.github.io/vnote/"
license=(MIT)
depends=(qt5-webengine qt5-svg)
makedepends=(git)
source=("git+https://github.com/tamlok/vnote.git#tag=v${pkgver}"
        "git+https://github.com/chjj/marked.git"
        "git+https://github.com/tamlok/hoedown.git")
sha256sums=('SKIP'
            'SKIP'
            'SKIP')

prepare() {
  cd "$pkgname"
  git submodule init
  git config 'submodule.src/utils/marked.url' "${srcdir}/marked"
  git config 'submodule.hoedown.url' "${srcdir}/hoedown"
  git submodule update

  install -d build
}

build() {
  cd "$pkgname/build"
  qmake ../VNote.pro
  make
}

package() {
  cd "$pkgname/build"
  make INSTALL_ROOT="$pkgdir" install
  install -Dm644 "$srcdir/$pkgname/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}