blob: c9570027ff38c12d15225b05a67bea39a2943bff (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
# Maintainer: Alfredo Ramos <alfredo dot ramos at yandex dot com>
# Contributor: Giacomo <giacomogiorgianni at gmail dot com>
pkgname=vokoscreen
_pkgver=2.4.21-beta
pkgver=${_pkgver/-/.}
pkgrel=2
pkgdesc='An easy to use screencast creator. Qt5 UI.'
arch=('i686' 'x86_64')
url='http://linuxecke.volkoh.de/vokoscreen/vokoscreen.html'
license=('GPL2')
depends=(
'qt5-x11extras' 'ffmpeg' 'lame'
'desktop-file-utils' 'xdg-utils' 'lsof'
)
optdepends=(
'pulseaudio-alsa: for PulseAudio support'
)
makedepends=('qt5-tools')
provides=("${pkgname}=${pkgver}")
conflicts=("${pkgname}-git")
source=(
"${pkgname}-${_pkgver}.tar.gz::https://github.com/vkohaupt/${pkgname}/archive/${_pkgver}.tar.gz"
'desktop_file.patch'
'fix_lrelease.patch'
)
sha512sums=(
'eef5a9d5c266020f3eae9f982442b4e58af393a449fe4300f015527fd804c91c9b7b759970f1edd39466ffab55aea38770d591418d8495d3fe0c7681dac4f43d'
'3ddc567f831b9f6e2672997a77a099cf8fdd5a6a1d79157738c1670c9106fd6c4e09d74287a770c19bac23dcb73a19ce69cc1ac893d4988f75c7ac35668f7a90'
'4c7e61e06a90de2815dd7564a9df050a939d5a3a1bb5514ee5808fd5277b5e6a12af80384f630e2c8429ca2decb318684b8f300a64846ae393c9482bc81425a4'
)
prepare() {
cd "${srcdir}"/${pkgname}-${_pkgver}
# Fix lrelease path
patch -Np1 < ../fix_lrelease.patch
# Desktop file description
patch -Np1 < ../desktop_file.patch
# Create build directory
mkdir -p "${srcdir}"/build
}
build() {
# Number of jobs
declare -i njobs=$(nproc)
if [[ ${njobs} -ge 8 ]]; then
njobs=$(( $njobs - 2 ))
fi
# Building package
cd "${srcdir}"/build
qmake-qt5 ../${pkgname}-${_pkgver} \
CONFIG+=release \
CONFIG+=c++14
make -j${njobs}
}
package() {
# Installing package
cd "${srcdir}"/build
make INSTALL_ROOT="${pkgdir}" install
}
|