blob: 065d6bc9267196a32d2b9cd8e28b8823e1bd0647 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Maintainer: Alfredo Ramos <alfredo dot ramos at yandex dot com>
# Contributor: Giacomo <giacomogiorgianni at gmail dot com>
pkgname=vokoscreen
_pkgver=2.4.12-beta
pkgver=${_pkgver/-/.}
pkgrel=1
pkgdesc='An easy to use screencast creator. Qt5 UI.'
arch=('i686' 'x86_64')
url='http://linuxecke.volkoh.de/vokoscreen/vokoscreen.html'
license=('GPL2')
depends=('ffmpeg' 'lame' 'qt5-x11extras' 'desktop-file-utils')
optdepends=(
'pulseaudio-alsa: for PulseAudio support'
)
makedepends=('qt5-tools')
provides=("${pkgname}=${pkgver}")
conflicts=("${pkgname}-git")
install=${pkgname}.install
source=(
"${pkgname}-${_pkgver}.tar.gz::https://github.com/vkohaupt/${pkgname}/archive/${_pkgver}.tar.gz"
'desktop_file.patch'
)
sha512sums=(
'f9dbc72243ff1bb31f2ea36a678d2d421a1e0eac43cb84e6969943c1fb3ff3b96370e97535b182a9805855dfb218e403e4e4622a3fbbb77791b5f8ef459891c3'
'3ddc567f831b9f6e2672997a77a099cf8fdd5a6a1d79157738c1670c9106fd6c4e09d74287a770c19bac23dcb73a19ce69cc1ac893d4988f75c7ac35668f7a90'
)
prepare() {
cd ${srcdir}/${pkgname}-${_pkgver}
# Desktop file description
patch -p1 < ../desktop_file.patch
# Create build directory
mkdir -p ${srcdir}/build
}
build() {
# Number of jobs
declare -i njobs=$(nproc)
if [[ ${njobs} -ge 8 ]]; then
njobs=$(( $njobs - 2 ))
fi
# Building package
cd ${srcdir}/build
qmake-qt5 ../${pkgname}-${_pkgver} \
CONFIG+=release \
CONFIG+=c++14 \
-spec linux-g++
make -j${njobs}
}
package() {
# Installing package
cd ${srcdir}/build
make INSTALL_ROOT=${pkgdir} install
}
|