blob: b7a971b6ec27b87bc2e50a4e1d0a46840eb20c70 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: Jose Riha <jose 1711 gmail com>
pkgname=vorta-git
_pkgname=vorta
pkgver=r582.17eb71a
pkgrel=1
pkgdesc="A GUI for BorgBackup (git)"
arch=('any')
url="https://github.com/borgbase/vorta"
license=('GPL')
provides=('vorta')
conflicts=('vorta')
depends=('borg' 'python-appdirs' 'python-pyqt5' 'python-peewee' 'python-paramiko' 'python-dateutil' 'python-secretstorage' 'python-psutil' 'python-llfuse' 'python-setuptools')
makedepends=('qt5-tools' 'python-pip' 'git')
options=(!emptydirs)
source=("$pkgname"::"git+https://github.com/borgbase/${_pkgname}")
sha256sums=('SKIP')
build() {
cd "${srcdir}/${pkgname}"
make translations-to-qm
python setup.py build
}
pkgver() {
cd "${srcdir}/${pkgname}"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
package() {
cd "${srcdir}/${pkgname}"
export PYTHONHASHSEED=0
python setup.py install --root="$pkgdir" --optimize=1 --skip-build
install -Dm644 package/icon-symbolic.svg \
"$pkgdir/usr/share/icons/hicolor/symbolic/apps/com.borgbase.Vorta-symbolic.svg"
install -Dm644 "src/$_pkgname/assets/metadata/com.borgbase.Vorta.appdata.xml" -t \
"$pkgdir/usr/share/metainfo"
install -Dm644 "src/$_pkgname/assets/metadata/com.borgbase.Vorta.desktop" -t \
"$pkgdir/usr/share/applications"
}
# vim:set ts=2 sw=2 et:
|