PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71

# Maintainer: Tymon3310 <aur@tymon3310.dev>
pkgname=vortex-git
pkgver=1.16.0.beta.5.r134.gbdec40633
pkgrel=1
pkgdesc="Nexus Mods' mod manager - native Linux build (Git Master)"
arch=('x86_64')
url="https://github.com/Nexus-Mods/Vortex"
license=('GPL-3.0-or-later')
depends=('c-ares' 'ffmpeg' 'gtk3' 'libevent' 'libvpx' 'libxslt' 'libxss'
  'minizip' 'libnotify' 'libappindicator-gtk3' 'nss' 'libsecret')
makedepends=('git' 'yarn' 'npm' 'nodejs' 'python' 'python-setuptools' 'dotnet-sdk-9.0')
provides=('vortex')
conflicts=('vortex')
install=vortex.install
source=("git+https://github.com/Nexus-Mods/Vortex.git#branch=master"
  "vortex.desktop"
  "vortex-handler.desktop")
sha256sums=('SKIP' 'SKIP' 'SKIP')

options=('!strip' '!debug')

pkgver() {
  cd "$srcdir/Vortex"
  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd "$srcdir/Vortex"
  _node_ver=$(node -v | sed 's/v//')
  sed -i "s/\"node\": \"[0-9.]*\"/\"node\": \">=$_node_ver\"/" package.json

  yarn install
}

build() {
  cd "$srcdir/Vortex"

  msg2 "Running pre-distribution setup..."
  yarn run predist

  msg2 "Compiling Webpack bundles..."
  yarn run build_dist

  cp assets/dotnetprobe app/assets/
  chmod +x app/assets/dotnetprobe

  msg2 "Packaging Electron application..."
  ./node_modules/.bin/electron-builder --linux dir --x64 --config electron-builder-config.json
}

package() {
  cd "$srcdir/Vortex/dist/linux-unpacked"

  install -dm755 "$pkgdir/opt/Vortex"
  cp -a . "$pkgdir/opt/Vortex/"

  install -dm755 "$pkgdir/opt/Vortex/resources/app.asar.unpacked/assets"
  install -Dm755 "$srcdir/Vortex/assets/dotnetprobe" \
    "$pkgdir/opt/Vortex/resources/app.asar.unpacked/assets/dotnetprobe"

  chmod 4755 "$pkgdir/opt/Vortex/chrome-sandbox"

  install -dm755 "$pkgdir/usr/bin"
  ln -sf /opt/Vortex/vortex "$pkgdir/usr/bin/vortex"

  install -Dm644 "$srcdir/vortex.desktop" "$pkgdir/usr/share/applications/vortex.desktop"

  install -Dm644 "$srcdir/vortex-handler.desktop" "$pkgdir/usr/share/applications/vortex-handler.desktop"

  install -Dm644 "$srcdir/Vortex/assets/images/vortex.png" "$pkgdir/usr/share/pixmaps/vortex.png"
}