PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35

# Maintainer: okrinoggen <okrinoggen@users.noreply.github.com>
pkgname=voxn
pkgver=0.3.1
pkgrel=1
pkgdesc="Local-first voice and text note-taking suite"
arch=('any')
url="https://github.com/okrinoggen33/voxn"
license=('MIT')
depends=('python' 'python-typer' 'sox' 'fzf' 'sqlite')
makedepends=('python-build' 'python-hatchling' 'python-installer' 'python-wheel')
optdepends=(
  'python-faster-whisper: local speech transcription backend'
  'ollama: default local LLM provider'
  'wl-clipboard: copy notes from voxn browse'
  'libnotify: desktop notifications'
  'yt-dlp: ingest video URLs'
  'poppler: ingest PDF files'
)
conflicts=('voxn-git')
source=("https://files.pythonhosted.org/packages/source/v/voxn/voxn-${pkgver}.tar.gz")
sha256sums=('a582d3edcaf8af03bb0998bcee528011f811350099391f3ef23604a8c6e607c4')

build() {
  cd "$pkgname-$pkgver"
  python -m build --wheel --no-isolation
}

package() {
  cd "$pkgname-$pkgver"
  python -m installer --destdir="$pkgdir" dist/*.whl
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  install -Dm644 man/*.1 -t "$pkgdir/usr/share/man/man1/"
  install -Dm644 systemd/voxn-index.path "$pkgdir/usr/lib/systemd/user/voxn-index.path"
  install -Dm644 packaging/systemd/voxn-index.service "$pkgdir/usr/lib/systemd/user/voxn-index.service"
}