blob: 5161148631183d9f235dbaca4c67a4793ab97f56 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
|
# Maintainer: Baptiste Augrain <daiyam@zokugun.org>.
# Inspired from the PKGBUILD for vscodium.
pkgname=vscodium-insiders-bin
pkgver=1.75.0.23020
pkgrel=1
pkgdesc="Binary releases of Code Insiders without branding/telemetry/licensing (binary release)"
arch=('x86_64' 'aarch64' 'armv7h')
url='https://github.com/VSCodium/vscodium.git'
license=('MIT')
depends=(
'fontconfig'
'libxtst'
'gtk3'
'cairo'
'alsa-lib'
'nss'
'libnotify'
'libxss'
'glibc>=2.28-4'
'libxkbfile'
)
optdepends=(
'gvfs: For move to trash functionality'
'libdbusmenu-glib: For KDE global menu'
)
provides=('codium-insiders')
conflicts=(
'vscodium-insiders'
'vscodium-insiders-git'
)
source=(
"${pkgname}.desktop"
"${pkgname}-uri-handler.desktop"
)
source_x86_64=(
"https://github.com/VSCodium/vscodium-insiders/releases/download/${pkgver}-insider/VSCodium-linux-x64-${pkgver}-insider.tar.gz"
)
source_armv7h=(
"https://github.com/VSCodium/vscodium-insiders/releases/download/${pkgver}-insider/VSCodium-linux-armhf-${pkgver}-insider.tar.gz"
)
source_aarch64=(
"https://github.com/VSCodium/vscodium-insiders/releases/download/${pkgver}-insider/VSCodium-linux-arm64-${pkgver}-insider.tar.gz"
)
sha256sums=('99dbc0d75aec1dbda70655fe3d9769aa2728116ae885e8be20c4b4f13ae1e80e'
'ccd83957fc14eaeeffc56762e864a8d313f99fa480c105eaecd832fb29d075ab')
sha256sums_x86_64=('f76d2af016363faa6cde93dda4099a6577c1a38a9826e24341979d58da0c1681')
sha256sums_aarch64=('55b5c62a32dc5ff2700f6cf414239ec2e23246ca0bf496d50ef94d3174ef2f28')
sha256sums_armv7h=('8245f014f6301a48752ec71cebff0d7c0bc53f4b4edfb52733f582891bca011e')
shopt -s extglob
package() {
install -d -m755 ${pkgdir}/usr/bin
install -d -m755 ${pkgdir}/usr/share/{${pkgname},applications,pixmaps}
install -d -m755 ${pkgdir}/usr/share/licenses/${pkgname}
cp -r ${srcdir}/!(${pkgname}*.desktop|VSCodium-*-${pkgver}-insider.tar.gz) ${pkgdir}/usr/share/${pkgname}
cp -r ${srcdir}/resources/app/LICENSE.txt ${pkgdir}/usr/share/licenses/${pkgname}
ln -s /usr/share/${pkgname}/bin/codium-insiders ${pkgdir}/usr/bin/codium-insiders
install -D -m644 ${pkgname}.desktop ${pkgdir}/usr/share/applications/${pkgname}.desktop
install -D -m644 ${pkgname}-uri-handler.desktop ${pkgdir}/usr/share/applications/${pkgname}-uri-handler.desktop
install -D -m644 ${srcdir}/resources/app/resources/linux/code.png ${pkgdir}/usr/share/pixmaps/${pkgname}.png
# Symlink shell completions
install -d -m755 ${pkgdir}/usr/share/zsh/site-functions
install -d -m755 ${pkgdir}/usr/share/bash-completion/completions
ln -s /usr/share/${pkgname}/resources/completions/zsh/_codium-insiders ${pkgdir}/usr/share/zsh/site-functions
ln -s /usr/share/${pkgname}/resources/completions/bash/codium-insiders ${pkgdir}/usr/share/bash-completion/completions
}
|