blob: 4be63beb87277e6ad3511f2c4defbe3a2620b1d3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# Maintainer: ml <>
pkgname=vt-cli
pkgver=0.9.5
pkgrel=1
pkgdesc='VirusTotal Command Line Interface'
arch=('i686' 'x86_64')
url=https://virustotal.github.io/vt-cli/
license=('Apache')
depends=('glibc')
makedepends=('go')
source=("https://github.com/VirusTotal/vt-cli/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz")
sha256sums=('97912c4f570fd3e2d5add016be64066ff5e6fb174d0814255f3d7d1dafc36505')
build() {
cd "${pkgname}-${pkgver}"
export CGO_ENABLED=1
export CGO_LDFLAGS="$LDFLAGS"
export CGO_CFLAGS="$CFLAGS"
export CGO_CPPFLAGS="$CPPFLAGS"
export CGO_CXXFLAGS="$CXXFLAGS"
export GOFLAGS='-buildmode=pie -trimpath -modcacherw'
go build -o build/vt -ldflags "-linkmode=external -X github.com/VirusTotal/vt-cli/cmd.Version=${pkgver}" ./vt
build/vt completion bash >vt.bash
build/vt completion zsh >vt.zsh
}
check() {
cd "${pkgname}-${pkgver}"
# yaml_test.go broken. fails upstream as well
go test -short ./utils/...
}
package() {
cd "${pkgname}-${pkgver}"
install -Dm755 build/vt -t "${pkgdir}/usr/bin"
install -Dm644 vt.bash "${pkgdir}/usr/share/bash-completion/completions/vt"
install -Dm644 vt.zsh "${pkgdir}/usr/share/zsh/site-functions/_vt"
install -Dm644 -t "${pkgdir}/usr/share/doc/${pkgname}" doc/*
}
|