blob: 76381960b9273113a5856e145d27708555d05da1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Maintainer: Felipe Contreras <felipe.contreras@gmail.com>
pkgname=vte3-nohang
pkgver=0.64.0
pkgrel=1
pkgdesc="Virtual Terminal Emulator widget (plus no-hang patch)"
url="https://wiki.gnome.org/Apps/Terminal/VTE"
arch=(x86_64)
license=(LGPL)
depends=(gtk3 pcre2 gnutls fribidi systemd-libs)
makedepends=(gobject-introspection vala git gtk-doc gperf meson)
source=("git+https://gitlab.gnome.org/GNOME/vte.git#tag=$pkgver"
fix-exit-regression.patch)
sha256sums=('SKIP'
'582edbac0c92cb023a4c0a8f70cb74c85606c139ab8c8f83f6093a21e3033a5c')
depends+=(vte-common)
provides=("vte3=$pkgver" libvte-2.91.so)
conflicts=(vte3)
prepare() {
cd vte
patch -p1 -i "$srcdir/fix-exit-regression.patch"
}
build() {
arch-meson vte build -D docs=true -D b_lto=false
meson compile -C build
}
check() {
meson test -C build --print-errorlogs
}
package() {
DESTDIR="$pkgdir" meson install -C build
# remove vte-common
rm -r "$pkgdir"/etc
rm -r "$pkgdir"/usr/lib/{systemd,vte-urlencode-cwd}
}
# vim: ts=2 et
|