blob: 544441189f55f5c1be551e760a1fb26988444bfc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: Daniel M. Capella <polyzen@archlinux.org>
# Contributor: Yufan You <ouuansteve at gmail>
_name=volar
pkgname=vue-language-server
pkgver=0.40.7
pkgrel=1
pkgdesc='Fast Vue Language Support Extension'
arch=('any')
url=https://github.com/johnsoncodehk/volar/tree/master/packages/server
license=('MIT')
depends=('nodejs')
makedepends=('npm' 'pnpm' 'typescript')
optdepends=('typescript: for use in typescript.serverPath')
source=("https://github.com/johnsoncodehk/$_name/archive/v$pkgver/$_name-$pkgver.tar.gz")
b2sums=('2ab69843e47d9020f06d2fb5c473d1114c29263afc2cc3165addc5db6394ab85039b6950405735e51cf8658beaf93c405602ef13596f1f48b76ad507d8e4d334')
prepare() {
cd $_name-$pkgver
pnpm install
}
build() {
cd $_name-$pkgver
npm run build
}
check() {
cd $_name-$pkgver
npm run test
}
package() {
cd $_name-$pkgver/packages/$pkgname
local _npmdir=/usr/lib/node_modules/@$_name/$pkgname
install -d "$pkgdir"{/usr/bin,"$_npmdir"}
ln -s "$_npmdir"/bin/$pkgname.js "$pkgdir"/usr/bin/$pkgname
# Prune devDependencies
rm -r node_modules
npm install --production
cp -r bin node_modules out package.json "$pkgdir/$_npmdir"
install -Dm644 -t "$pkgdir"/usr/share/licenses/$pkgname LICENSE
}
|