blob: 975c5df077e0535cf1e7ed69705590dec2cf111c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Daniel M. Capella <polyzen@archlinux.org>
# Contributor: Yufan You <ouuansteve at gmail>
_name=volar
pkgname=vue-language-server
pkgver=0.37.5
pkgrel=1
pkgdesc='Fast Vue Language Support Extension'
arch=('any')
url=https://github.com/johnsoncodehk/volar/tree/master/packages/server
license=('MIT')
depends=('nodejs')
makedepends=('npm' 'pnpm' 'typescript')
optdepends=('typescript: for use in typescript.serverPath')
source=("https://github.com/johnsoncodehk/$_name/archive/v$pkgver/$_name-$pkgver.tar.gz")
b2sums=('455a68a0f27b59bcb1987bd2a71a5116d64956ae6dbf95e81972f3442441e06a265e1bb3dae1fbcb32d4fdb7bee355bc872ab83c4f41f164a97b24359f6c8650')
prepare() {
cd $_name-$pkgver
pnpm install
}
build() {
cd $_name-$pkgver
npm run build
}
check() {
cd $_name-$pkgver
npm run test
}
package() {
cd $_name-$pkgver/packages/$pkgname
local _npmdir=/usr/lib/node_modules/@$_name/$pkgname
install -d "$pkgdir"{/usr/bin,"$_npmdir"}
ln -s "$_npmdir"/bin/$pkgname.js "$pkgdir"/usr/bin/$pkgname
# Prune devDependencies
rm -r node_modules
npm install --production
cp -r bin node_modules out package.json "$pkgdir/$_npmdir"
install -Dm644 -t "$pkgdir"/usr/share/licenses/$pkgname LICENSE
}
# vim:set ts=2 sw=2 et:
|