blob: 0efaf90a3b6cf5efc5ed9f9808a9664874b0db4a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Daniel M. Capella <polyzen@archlinux.org>
# Contributor: Yufan You <ouuansteve at gmail>
_name=volar
pkgname=vue-language-server
pkgver=0.33.2
pkgrel=1
pkgdesc='Fast Vue Language Support Extension'
arch=('any')
url=https://github.com/johnsoncodehk/volar/tree/master/packages/server
license=('MIT')
depends=('nodejs')
makedepends=('npm' 'pnpm' 'typescript')
optdepends=('typescript: for use in typescript.serverPath')
source=("https://github.com/johnsoncodehk/volar/archive/v$pkgver/$_name-$pkgver.tar.gz")
b2sums=('71998f38277651a5ba02e5d5b4b1d94e69a6b624cea6914e70ca050b6339e25024fe548b7a791f6e646dc8b3b188095da66d336a83a2e2a3a9a1d2a92c5d5929')
prepare() {
cd $_name-$pkgver
pnpm install
}
build() {
cd $_name-$pkgver
npm run build
}
check() {
cd $_name-$pkgver
npm run test
}
package() {
cd $_name-$pkgver/packages/$pkgname
local _npmdir=/usr/lib/node_modules/@volar/$pkgname
install -d "$pkgdir"{/usr/bin,"$_npmdir"}
ln -s "$_npmdir"/bin/$pkgname.js "$pkgdir"/usr/bin/$pkgname
# Prune devDependencies
rm -r node_modules
npm install --production
cp -r bin node_modules out package.json "$pkgdir/$_npmdir"
install -Dm644 -t "$pkgdir"/usr/share/licenses/$pkgname LICENSE
}
# vim:set ts=2 sw=2 et:
|