blob: 3903dc3d5eefb168479afac8b27d79aa8755cc9d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
# Contributor: Eric Engestrom <aur [at] engestrom [dot] ch>
pkgname=('vulkan-caps-viewer-x11' 'vulkan-caps-viewer-wayland')
pkgbase=vulkan-caps-viewer
pkgver=4.11
pkgrel=1
epoch=1
pkgdesc="Vulkan Hardware Capability Viewer"
arch=('x86_64' 'aarch64')
url="https://vulkan.gpuinfo.org"
license=('LGPL-3.0-or-later')
depends=(
'hicolor-icon-theme'
'qt6-base'
'vulkan-icd-loader'
)
makedepends=('git')
source=("git+https://github.com/SaschaWillems/VulkanCapsViewer.git#tag=$pkgver"
'git+https://github.com/KhronosGroup/Vulkan-Headers.git')
sha256sums=('e7488b8da8d038f55278a84423556b40792a273414de65448938c85789352a8a'
'SKIP')
prepare() {
# Create build directories
mkdir -p build-x11 build-wayland
cd VulkanCapsViewer
git submodule init
git config submodule.Vulkan-Headers.url "$srcdir/Vulkan-Headers"
git -c protocol.file.allow=always submodule update
}
build() {
# X11
pushd build-x11
qmake6 ../VulkanCapsViewer \
DEFINES+=X11 \
CONFIG+=release \
PREFIX=/usr
make
popd
# Wayland
pushd build-wayland
qmake6 ../VulkanCapsViewer \
DEFINES+=WAYLAND \
CONFIG+=release \
PREFIX=/usr
make
popd
}
package_vulkan-caps-viewer-x11() {
pkgdesc+=" (X11)"
depends+=('libxcb')
provides=('vulkan-caps-viewer')
conflicts=('vulkan-caps-viewer')
cd build-x11
make INSTALL_ROOT="$pkgdir/" install
install -m644 ../VulkanCapsViewer/gfx/android_icon_256.png \
"$pkgdir"/usr/share/icons/hicolor/256x256/apps/vulkanCapsViewer.png
}
package_vulkan-caps-viewer-wayland() {
pkgdesc+=" (Wayland)"
depends+=('wayland')
provides=('vulkan-caps-viewer')
conflicts=('vulkan-caps-viewer')
cd build-wayland
make INSTALL_ROOT="$pkgdir/" install
install -m644 ../VulkanCapsViewer/gfx/android_icon_256.png \
"$pkgdir"/usr/share/icons/hicolor/256x256/apps/vulkanCapsViewer.png
}
|