blob: d64bd43b81ec44636d8a0248b6b1c2b5acbc02f2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
# Contributor: Eric Engestrom <aur [at] engestrom [dot] ch>
pkgname=('vulkan-caps-viewer-x11' 'vulkan-caps-viewer-wayland')
pkgbase=vulkan-caps-viewer
pkgver=3.33
pkgrel=2
epoch=1
pkgdesc="Vulkan Hardware Capability Viewer"
arch=('x86_64' 'aarch64')
url="https://vulkan.gpuinfo.org"
license=('LGPL-3.0-or-later')
makedepends=('git' 'qt5-wayland' 'qt5-x11extras' 'vulkan-icd-loader')
_commit=1008cecb054ab15acf51353ac85ffd8ebb135cc4 # tags/3.33^0
source=("git+https://github.com/SaschaWillems/VulkanCapsViewer.git#commit=$_commit"
'git+https://github.com/KhronosGroup/Vulkan-Headers.git')
sha256sums=('SKIP'
'SKIP')
pkgver() {
cd VulkanCapsViewer
git describe --tags | sed 's/_fixed//;s/-/+/g'
}
prepare() {
cd VulkanCapsViewer
git submodule init
git config submodule.Vulkan-Headers.url "$srcdir/Vulkan-Headers"
git -c protocol.file.allow=always submodule update
# Create build directories
mkdir -p build-x11 build-wayland
}
build() {
cd VulkanCapsViewer
# X11
pushd build-x11
qmake-qt5 \
DEFINES+=X11 \
CONFIG+=release \
PREFIX=/usr
make
popd
# Wayland
pushd build-wayland
qmake-qt5 \
DEFINES+=WAYLAND \
CONFIG+=release \
PREFIX=/usr
make
popd
}
package_vulkan-caps-viewer-x11() {
pkgdesc+=" (X11)"
depends=('hicolor-icon-theme' 'vulkan-icd-loader' 'qt5-x11extras')
provides=('vulkan-caps-viewer')
conflicts=('vulkan-caps-viewer')
cd VulkanCapsViewer/build-x11
make INSTALL_ROOT="$pkgdir/" install
install -m644 gfx/android_icon_256.png \
"$pkgdir"/usr/share/icons/hicolor/256x256/apps/vulkanCapsViewer.png
}
package_vulkan-caps-viewer-wayland() {
pkgdesc+=" (Wayland)"
depends=('hicolor-icon-theme' 'vulkan-icd-loader' 'qt5-wayland')
provides=('vulkan-caps-viewer')
conflicts=('vulkan-caps-viewer')
cd VulkanCapsViewer/build-wayland
make INSTALL_ROOT="$pkgdir/" install
install -m644 gfx/android_icon_256.png \
"$pkgdir"/usr/share/icons/hicolor/256x256/apps/vulkanCapsViewer.png
}
|