blob: 2816f78d16abb1cd89a9d524bea13ade7d9640f1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: Eric Engestrom <aur [at] engestrom [dot] ch>
pkgname=vulkan-caps-viewer
pkgver=3.01
pkgrel=1
pkgdesc='Vulkan Hardware Capability Viewer'
url='http://vulkan.gpuinfo.org/'
arch=('x86_64')
license=('GPL2')
source=("git+https://github.com/SaschaWillems/VulkanCapsViewer#tag=$pkgver"
"git+https://github.com/KhronosGroup/Vulkan-Headers")
sha1sums=('SKIP'
'SKIP')
makedepends=(git)
depends=(vulkan-icd-loader qt5-base)
optdepends=(qt5-x11extras qt5-wayland)
prepare() {
cd VulkanCapsViewer
git submodule init
git config submodule.Vulkan-Headers.url "$srcdir/Vulkan-Headers"
git submodule update
}
build() {
cd VulkanCapsViewer
qmake \
QMAKE_CFLAGS="$CFLAGS" \
QMAKE_CXXFLAGS="$CXXFLAGS" \
QMAKE_LFLAGS="$LDFLAGS" \
PREFIX=/usr
make
}
package() {
cd VulkanCapsViewer
make INSTALL_ROOT="$pkgdir" install
# There's a bug preventing this from being installed automatically
install -Dm644 gfx/android_icon_256.png \
"$pkgdir"/usr/share/icons/hicolor/256x256/apps/vulkanCapsViewer.png
}
|