blob: 41b3ca4968aa31b907e8ae362f84139422eb5403 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Maintainer: Mark Wagie <mark dot wagie at tutanota dot com>
# Co-Maintainer: Eric Engestrom <aur [at] engestrom [dot] ch>
pkgname=vulkan-caps-viewer-wayland
pkgver=3.27
pkgrel=2
epoch=1
pkgdesc="Vulkan Hardware Capability Viewer"
arch=('x86_64' 'aarch64')
url="https://vulkan.gpuinfo.org"
license=('GPL2')
depends=('vulkan-icd-loader' 'qt5-wayland')
makedepends=('git')
provides=("${pkgname%-*}")
conflicts=("${pkgname%-*}")
_commit=0f9fd085cf82c46f8391a5ec5b4986e35c8ded3b # tags/3.27^0
source=("git+https://github.com/SaschaWillems/VulkanCapsViewer.git#commit=$_commit"
'git+https://github.com/KhronosGroup/Vulkan-Headers.git'
'https://github.com/SaschaWillems/VulkanCapsViewer/pull/155.patch')
sha256sums=('SKIP'
'SKIP'
'cd6a775c44cacc8549346cb31696822646806f51655a36cf834ef9029d201976')
pkgver() {
cd "$srcdir/VulkanCapsViewer"
git describe --tags | sed 's/_fixed//;s/-/+/g'
}
prepare() {
cd "$srcdir/VulkanCapsViewer"
git submodule init
git config submodule.Vulkan-Headers.url "$srcdir/Vulkan-Headers"
git -c protocol.file.allow=always submodule update
# Fix Wayland build
patch -Np1 -i ../155.patch
}
build() {
cd "$srcdir/VulkanCapsViewer"
qmake-qt5 \
DEFINES+=WAYLAND \
CONFIG+=release \
PREFIX=/usr
make
}
package() {
cd "$srcdir/VulkanCapsViewer"
make INSTALL_ROOT="$pkgdir/" install
# There's a bug preventing this from being installed automatically
install -m644 gfx/android_icon_256.png \
"$pkgdir"/usr/share/icons/hicolor/256x256/apps/vulkanCapsViewer.png
}
|