blob: 2e7549a13d30f194d057e67565ed611dd7fea51e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
# Co-Maintainer: Eric Engestrom <aur [at] engestrom [dot] ch>
pkgname=vulkan-caps-viewer-x11
pkgver=3.33
pkgrel=1
epoch=1
pkgdesc="Vulkan Hardware Capability Viewer"
arch=('x86_64' 'aarch64')
url="https://vulkan.gpuinfo.org"
license=('LGPL-3.0-or-later')
depends=('vulkan-icd-loader' 'qt5-x11extras')
makedepends=('git')
provides=("${pkgname%-*}")
conflicts=("${pkgname%-*}")
_commit=1008cecb054ab15acf51353ac85ffd8ebb135cc4 # tags/3.33^0
source=("git+https://github.com/SaschaWillems/VulkanCapsViewer.git#commit=$_commit"
'git+https://github.com/KhronosGroup/Vulkan-Headers.git')
sha256sums=('SKIP'
'SKIP')
pkgver() {
cd VulkanCapsViewer
git describe --tags | sed 's/_fixed//;s/-/+/g'
}
prepare() {
cd VulkanCapsViewer
git submodule init
git config submodule.Vulkan-Headers.url "$srcdir/Vulkan-Headers"
git -c protocol.file.allow=always submodule update
}
build() {
cd VulkanCapsViewer
qmake-qt5 \
DEFINES+=X11 \
CONFIG+=release \
PREFIX=/usr
make
}
package() {
cd VulkanCapsViewer
make INSTALL_ROOT="$pkgdir/" install
# There's a bug preventing this from being installed automatically
install -m644 gfx/android_icon_256.png \
"$pkgdir"/usr/share/icons/hicolor/256x256/apps/vulkanCapsViewer.png
}
|