blob: 7a813cc903e38f673e620986ff779a886f9c2f7c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor: Fat Cat <carlos dot manuel250 at gmail dot com>
pkgname=vundle-git
pkgver=0.10.2.605.fef1c2f
pkgrel=1
pkgdesc='Plug-in manager for Vim'
url='https://github.com/VundleVim/Vundle.vim'
arch=('any')
license=('MIT')
depends=('vim>=7.0')
makedepends=('git')
provides=('vundle')
conflicts=('vundle')
install=vundle.install
source=(${pkgname}::git+https://github.com/VundleVim/Vundle.vim)
sha512sums=('SKIP')
pkgver() {
cd ${pkgname}
printf "%s.%s.%s" \
"$(git describe --tags --abbrev=0|sed 's/^v//')" \
"$(git rev-list --count HEAD)" \
"$(git rev-parse --short HEAD)"
}
prepare() {
cd ${pkgname}
sed -r 's|(set rtp)|" \1|' -i README.md
}
package() {
cd ${pkgname}
vimpath="${pkgdir}/usr/share/vim/vimfiles"
mkdir -p "${vimpath}/doc"
cp -R doc "${vimpath}"
mkdir -p "${vimpath}/autoload"
cp -R autoload "${vimpath}"
install -Dm 644 LICENSE-MIT.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
install -Dm 644 README.md "${pkgdir}/usr/share/doc/${pkgname}/README"
}
# vim: ts=2 sw=2 et:
|