PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

# Maintainer: Marius Lindvall <(firstname) {cat} varden {dog} info>

pkgname=vvdec-git
pkgver=1.1.0.r1.g8372ca4
pkgrel=1
pkgdesc="Fraunhofer Versatile Video Decoder (VVdeC)"
arch=('x86_64')
url='https://github.com/fraunhoferhhi/vvdec'
license=('custom')
depends=('gcc-libs')
makedepends=('git' 'cmake>=3.12' 'gcc>=7')
provides=('vvdec')
conflicts=('vvdec')
source=("git+https://github.com/fraunhoferhhi/vvdec.git")
sha256sums=('SKIP')

pkgver() {
	cd "${srcdir}/vvdec"
	git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
	export CFLAGS+=" ${CPPFLAGS}"
	export CXXFLAGS+=" ${CPPFLAGS}"
	cmake -B build -S "${srcdir}/vvdec" \
		-DCMAKE_BUILD_TYPE=Release \
		-DVVDEC_ENABLE_INSTALL:BOOL=ON \
		-DBUILD_SHARED_LIBS:BOOL=ON \
		-Wno-dev
	make -C build
}

check() {
	export CFLAGS+=" ${CPPFLAGS}"
	export CXXFLAGS+=" ${CPPFLAGS}"
	cmake -B build -S "${srcdir}/vvdec" \
		-DCMAKE_BUILD_TYPE=Release \
		-DVVDEC_ENABLE_INSTALL:BOOL=ON \
		-DVVDEC_ENABLE_BITSTREAM_DOWNLOAD:BOOL=ON \
		-DBUILD_SHARED_LIBS:BOOL=ON \
		-Wno-dev
	make -C build test
}

package() {
	make -C build install
	cd "${srcdir}/vvdec"
	cp -r "install" "$pkgdir/usr"
	mkdir -p "$pkgdir/usr/share/licenses/vvdec"
	install -Dm644 "LICENSE.txt" "$pkgdir/usr/share/licenses/vvdec/"
}