PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57

# Maintainer: Markus Kitsinger (SwooshyCueb) <root@swooshalicio.us>

pkgname=vx68k-git
pkgver=2.alpha.1.r15.gdba943d
pkgrel=1
pkgdesc="Virtual X68000 - emulator of Sharp X68000 implemented in C++"
arch=('i686' 'x86_64')
depends=('libvm68k')
makedepends=('git' 'make' 'pkg-config' 'autoconf' 'automake')
#checkdepends=('cppunit')
url="https://www.vx68k.org/vx68k"
license=('GPL3')
source=(${pkgname%-git}::git+https://bitbucket.org/kazssym/vx68k.git)
sha256sums=('SKIP')
provides=('vx68k')
conflicts=('vx68k')

pkgver() {
	cd "$srcdir/${pkgname%-git}"

	# This repo doesn't have tags as of this writing, so we take the version
	# from configure.ac:
	verpart=$(tr -d '\n' < configure.ac | grep -oP 'AC_INIT\(\s*\[[^\]]+\]\s*,\s*\[\K[^\]]+')
	# for the revcount, just use number of commits in the branch:
	revpart=$(git rev-list --count HEAD)

	hash=$(git rev-parse --short HEAD)

	echo "${verpart//-/.}.r${revpart}.g${hash}"
}

prepare() {
	cd "$srcdir/${pkgname%-git}"

	# configure looks for the wrong package, fix
	sed -i 's/PKG_CHECK_MODULES(\[LIBVM68K\], \[vm68k\])/PKG_CHECK_MODULES([LIBVM68K], [libvm68k])/' configure.ac
}

build() {
	cd "$srcdir/${pkgname%-git}"

	autoreconf
	./configure --prefix=/usr
	make
}

# configure looks for cppunit, but it's never used, and make check doesn't do anything.
# this might change in future?
#check() {
#	cd "$srcdir/${pkgname%-git}"
#	make check
#}

package() {
	cd "$srcdir/${pkgname%-git}"
	make DESTDIR="$pkgdir" install
}