PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56

# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=wabt-git
pkgver=1.0.32.r51.g539c541b
pkgrel=2
pkgdesc="The WebAssembly binary toolkit"
arch=('i686' 'x86_64')
url="https://github.com/WebAssembly/wabt"
license=('Apache')
depends=('gcc-libs' 'glibc')
makedepends=('git' 'clang' 'cmake' 'gcc')
provides=("wabt=$pkgver")
conflicts=('wabt')
options=('staticlibs')
source=("git+https://github.com/WebAssembly/wabt.git")
sha256sums=('SKIP')


prepare() {
  cd "wabt"

  git submodule update --init --recursive
}

pkgver() {
  cd "wabt"

  _tag=$(git tag -l --sort -v:refname | grep -E '^v?[0-9\.]+$' | head -n1)
  _rev=$(git rev-list --count $_tag..HEAD)
  _hash=$(git rev-parse --short HEAD)
  printf "%s.r%s.g%s" "$_tag" "$_rev" "$_hash" | sed 's/^v//'
}

build() {
  cd "wabt"

  cmake \
    -B "_build" \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX="/usr" \
    -DCMAKE_INSTALL_LIBDIR="lib" \
    ./
  make -C "_build"
}

check() {
  cd "wabt"

  #make -C "_build" check
}

package() {
  cd "wabt"

  make -C "_build" DESTDIR="$pkgdir" install
}